CP-307933: [prepare]: introduce DB_ACCESS2

This provides direct access to a Value.t when known, which avoids having to serialize and deserialize a Value.t just to read it.

Not yet used, no functional change.

Signed-off-by: Edwin Török <[email protected]>

Author: edwintorok

ocaml/database/db_interface.mli

@@ -96,7 +96,8 @@ module type DB_ACCESS_FIELD = sig
 
   type field_out
 
-  val read_field_where : Db_ref.t -> Db_cache_types.where_record -> field list
+  val read_field_where :
+    Db_ref.t -> Db_cache_types.where_record -> field_out list
   (** [read_field_where {tbl,return,where_field,where_value}] returns a
       		list of the [return] fields in table [tbl] where the [where_field]
       		equals [where_value] *)
@@ -106,11 +107,12 @@ module type DB_ACCESS_FIELD = sig
   (** [create_row tbl kvpairs ref] create a new row in [tbl] with
       		key [ref] and contents [kvpairs] *)
 
-  val write_field : Db_ref.t -> table -> db_ref -> field_name -> field -> unit
+  val write_field :
+    Db_ref.t -> table -> db_ref -> field_name -> field_in -> unit
   (** [write_field context tbl ref fld val] changes field [fld] to [val] in
       		row [ref] in table [tbl] *)
 
-  val read_field : Db_ref.t -> table -> field_name -> db_ref -> field
+  val read_field : Db_ref.t -> table -> field_name -> db_ref -> field_out
   (** [read_field context tbl fld ref] returns the value of field [fld]
       		in row [ref] in table [tbl] *)
 
@@ -133,3 +135,15 @@ module type DB_ACCESS = sig
   include
     DB_ACCESS_FIELD with type field_in = string and type field_out = string
 end
+
+module type DB_ACCESS2 = sig
+  include DB_ACCESS_COMMON
+
+  include
+    DB_ACCESS_FIELD
+      with type field_in = Schema.Value.t
+       and type field_out = Schema.maybe_cached_value
+
+  module Compat :
+    DB_ACCESS_FIELD with type field_in = string and type field_out = string
+end

ocaml/database/db_interface_compat.ml

@@ -0,0 +1,61 @@
+(*
+ * Copyright (C) Cloud Software Group
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU Lesser General Public License as published
+ * by the Free Software Foundation; version 2.1 only. with the special
+ * exception on linking described in file LICENSE.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU Lesser General Public License for more details.
+ *)
+
+open Db_interface
+
+module OfCached (DB : DB_ACCESS2) : DB_ACCESS = struct
+  include DB include DB.Compat
+end
+
+module OfCompat (DB : DB_ACCESS) : DB_ACCESS2 = struct
+  module Compat = DB
+  include Compat
+
+  type field_in = Schema.Value.t
+
+  type field_out = Schema.maybe_cached_value
+
+  let field_of_compat = Schema.CachedValue.of_string
+
+  let compat_of_field = Schema.Value.marshal
+
+  let regular_field_of_compat (k, v) = (k, field_of_compat v)
+
+  let regular_fields_of_compat l = List.map regular_field_of_compat l
+
+  let compat_of_regular_field (k, v) = (k, compat_of_field v)
+
+  let compat_of_regular_fields l = List.map compat_of_regular_field l
+
+  let db_record_of_compat (regular, assoc) =
+    (regular_fields_of_compat regular, assoc)
+
+  let db_record_entry_of_compat (ref, record) = (ref, db_record_of_compat record)
+
+  let read_field_where t where =
+    read_field_where t where |> List.map field_of_compat
+
+  let create_row t tbl fields ref =
+    create_row t tbl (compat_of_regular_fields fields) ref
+
+  let write_field t tbl ref fld field =
+    write_field t tbl ref fld (compat_of_field field)
+
+  let read_field t tbl fld ref = read_field t tbl fld ref |> field_of_compat
+
+  let read_record t tbl ref = read_record t tbl ref |> db_record_of_compat
+
+  let read_records_where t tbl expr =
+    read_records_where t tbl expr |> List.map db_record_entry_of_compat
+end

ocaml/database/db_interface_compat.mli

@@ -0,0 +1,18 @@
+(*
+ * Copyright (C) Cloud Software Group
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU Lesser General Public License as published
+ * by the Free Software Foundation; version 2.1 only. with the special
+ * exception on linking described in file LICENSE.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU Lesser General Public License for more details.
+ *)
+open Db_interface
+
+module OfCached : functor (_ : DB_ACCESS2) -> DB_ACCESS
+
+module OfCompat : functor (_ : DB_ACCESS) -> DB_ACCESS2