build: move dsp56300 meson.build to packagefiles

The cross-compilation and platform-specific configuration is specific
to xemu's build environment. Use Meson's patch_directory mechanism
to overlay the xemu-specific meson.build onto the upstream source.

Author: mborgerson

subprojects/.gitignore

@@ -39,4 +39,4 @@ genconfig
 curl-*
 json-*
 SDL3-*
-dsp56300
+/dsp56300

subprojects/dsp56300.wrap

@@ -2,6 +2,7 @@
 url=https://github.com/mborgerson/dsp56300
 revision=main
 depth=1
+patch_directory=dsp56300
 
 [provide]
 dsp56300-emu-ffi=dsp56300_dep

subprojects/packagefiles/dsp56300/meson.build

@@ -0,0 +1,66 @@
+project('dsp56300', version: '0.1.0')
+
+dsp56300_src = meson.current_source_dir()
+
+# Determine Rust target triple for cross-compilation.
+# Map Meson's host_machine to Rust target triples.
+host_cpu = host_machine.cpu_family()
+host_os = host_machine.system()
+
+if host_os == 'darwin'
+  if host_cpu == 'aarch64'
+    rust_target = 'aarch64-apple-darwin'
+  else
+    rust_target = 'x86_64-apple-darwin'
+  endif
+elif host_os == 'windows'
+  if host_cpu == 'aarch64'
+    rust_target = 'aarch64-pc-windows-gnullvm'
+  else
+    rust_target = 'x86_64-pc-windows-gnu'
+  endif
+elif host_os == 'linux'
+  if host_cpu == 'aarch64'
+    rust_target = 'aarch64-unknown-linux-gnu'
+  else
+    rust_target = 'x86_64-unknown-linux-gnu'
+  endif
+else
+  error('Unsupported host OS: ' + host_os)
+endif
+
+# GNU/LLVM targets always produce .a; only MSVC would produce .lib.
+lib_name = 'libdsp56300_emu_ffi.a'
+
+cargo_target_dir = dsp56300_src / 'target' / rust_target / 'release'
+
+dsp56300_lib = custom_target(
+  'dsp56300_emu_ffi',
+  command: [
+    'sh', '-c',
+    'cargo build --release -p dsp56300-emu-ffi --no-default-features --target "$1" --manifest-path "$2/Cargo.toml" && cp "$3/$4" "$5"',
+    '--', rust_target, dsp56300_src, cargo_target_dir, lib_name, '@OUTPUT@'
+  ],
+  output: lib_name,
+  build_by_default: true,
+  build_always_stale: true,
+  console: true,
+)
+
+# System libraries needed by the Rust staticlib.
+system_link_args = [dsp56300_lib.full_path()]
+if host_os == 'linux'
+  system_link_args += ['-lpthread', '-ldl', '-lm']
+elif host_os == 'darwin'
+  system_link_args += ['-lpthread', '-lm', '-framework', 'Security']
+elif host_os == 'windows'
+  system_link_args += ['-lbcrypt', '-lntdll', '-luserenv', '-lws2_32']
+endif
+
+dsp56300_dep = declare_dependency(
+  sources: dsp56300_lib,
+  link_args: system_link_args,
+  include_directories: include_directories('crates/emu-ffi/include'),
+)
+
+meson.override_dependency('dsp56300-emu-ffi', dsp56300_dep)