flake.nix

{
  description = "Build a cargo workspace";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    crane = {
      url = "github:ipetkov/crane";
    };

    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.rust-analyzer-src.follows = "";
    };

    flake-utils.url = "github:numtide/flake-utils";

    advisory-db = {
      url = "github:rustsec/advisory-db";
      flake = false;
    };
  };

  outputs = { self, nixpkgs, crane, fenix, flake-utils, advisory-db, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = nixpkgs.legacyPackages.${system};

        inherit (pkgs) lib;

        craneLib = crane.mkLib pkgs;
        src = craneLib.cleanCargoSource ./.;

        # Common arguments can be set here to avoid repeating them later
        commonArgs = {
          inherit src;
          strictDeps = true;

          buildInputs = [
            # Add additional build inputs here
          ] ++ lib.optionals pkgs.stdenv.isDarwin [
            # Additional darwin specific inputs can be set here
            pkgs.libiconv
          ];

          # Additional environment variables can be set directly
          # MY_CUSTOM_VAR = "some value";
        };

        craneLibLLvmTools = craneLib.overrideToolchain
          (fenix.packages.${system}.complete.withComponents [
            "cargo"
            "llvm-tools"
            "rustc"
          ]);

        # Build *just* the cargo dependencies (of the entire workspace),
        # so we can reuse all of that work (e.g. via cachix) when running in CI
        # It is *highly* recommended to use something like cargo-hakari to avoid
        # cache misses when building individual top-level-crates
        cargoArtifacts = craneLib.buildDepsOnly commonArgs;

        individualCrateArgs = commonArgs // {
          inherit cargoArtifacts;
          inherit (craneLib.crateNameFromCargoToml { inherit src; }) version;
          # NB: we disable tests since we'll run them all via cargo-nextest
          doCheck = false;
        };

        fileSetForCrate = crate: lib.fileset.toSource {
          root = ./.;
          fileset = lib.fileset.unions [
            ./Cargo.toml
            ./Cargo.lock
            ./olmonoko-common
            crate
          ];
        };

        # Build the top-level crates of the workspace as individual derivations.
        # This allows consumers to only depend on (and build) only what they need.
        # Though it is possible to build the entire workspace as a single derivation,
        # so this is left up to you on how to organize things
        olmonokod = craneLib.buildPackage (individualCrateArgs // {
          pname = "olmonokod";
          cargoExtraArgs = "-p olmonokod";
          src = fileSetForCrate ./olmonokod;
        });
        olmonoko-backend = craneLib.buildPackage (individualCrateArgs // {
          pname = "olmonoko-backend";
          cargoExtraArgs = "-p olmonoko-backend";
          src = fileSetForCrate ./olmonoko-backend;
        });
      in
      {
        checks = {
          # Build the crates as part of `nix flake check` for convenience
          inherit olmonokod olmonoko-backend;

          # Run clippy (and deny all warnings) on the workspace source,
          # again, reusing the dependency artifacts from above.
          #
          # Note that this is done as a separate derivation so that
          # we can block the CI if there are issues here, but not
          # prevent downstream consumers from building our crate by itself.
          olmonoko-workspace-clippy = craneLib.cargoClippy (commonArgs // {
            inherit cargoArtifacts;
            cargoClippyExtraArgs = "--all-targets -- --deny warnings";
          });

          olmonoko-workspace-doc = craneLib.cargoDoc (commonArgs // {
            inherit cargoArtifacts;
          });

          # Check formatting
          olmonoko-workspace-fmt = craneLib.cargoFmt {
            inherit src;
          };

          # # Audit dependencies
          # olmonoko-workspace-audit = craneLib.cargoAudit {
          #   inherit src advisory-db;
          # };

          # # Audit licenses
          # olmonoko-workspace-deny = craneLib.cargoDeny {
          #   inherit src;
          # };

          # # Run tests with cargo-nextest
          # # Consider setting `doCheck = false` on other crate derivations
          # # if you do not want the tests to run twice
          # olmonoko-workspace-nextest = craneLib.cargoNextest (commonArgs // {
          #   inherit cargoArtifacts;
          #   partitions = 1;
          #   partitionType = "count";
          # });
          #
          # # Ensure that cargo-hakari is up to date
          # olmonoko-workspace-hakari = craneLib.mkCargoDerivation {
          #   inherit src;
          #   pname = "olmonoko-workspace-hakari";
          #   cargoArtifacts = null;
          #   doInstallCargoArtifacts = false;
          #
          #   buildPhaseCargoCommand = ''
          #     cargo hakari generate --diff  # workspace-hack Cargo.toml is up-to-date
          #     cargo hakari manage-deps --dry-run  # all workspace crates depend on workspace-hack
          #     cargo hakari verify
          #   '';
          #
          #   nativeBuildInputs = [
          #     pkgs.cargo-hakari
          #   ];
          # };
        };

        packages = {
          inherit olmonokod olmonoko-backend;
        } // lib.optionalAttrs (!pkgs.stdenv.isDarwin) {
          olmonoko-workspace-llvm-coverage = craneLibLLvmTools.cargoLlvmCov (commonArgs // {
            inherit cargoArtifacts;
          });
        };

        apps = {
          olmonokod = flake-utils.lib.mkApp {
            drv = olmonokod;
          };
          olmonoko-backend = flake-utils.lib.mkApp {
            drv = olmonoko-backend;
          };
        };

        devShells.default = craneLib.devShell {
          # Inherit inputs from checks.
          checks = self.checks.${system};

          # Additional dev-shell environment variables can be set directly
          # MY_CUSTOM_DEVELOPMENT_VAR = "something else";

          # Extra inputs can be added here; cargo and rustc are provided by default.
          packages = [
            # pkgs.cargo-hakari

            # Docker
            pkgs.docker
            pkgs.docker-compose

            # Rust
            # pkgs.rust-bin.nightly.latest.default
            # pkgs.cargo # Package manager
            pkgs.cargo-audit # Manual checks against security vulnerabilities
            pkgs.rustfmt # Formatting
            pkgs.bacon # Constant feedback
            pkgs.clippy # Tips & tricks

            # SQL Helper
            pkgs.sqlx-cli
          ];
        };
      });
}