JBR-4578 Add Java ATK Wrapper

.github/workflows/build-cross-compile.yml

@@ -113,7 +113,7 @@ jobs:
               g++-${{ inputs.gcc-major-version }} \
               gcc-${{ inputs.gcc-major-version }}-${{ matrix.gnu-arch }}-linux-gnu${{ matrix.gnu-abi}} \
               g++-${{ inputs.gcc-major-version }}-${{ matrix.gnu-arch }}-linux-gnu${{ matrix.gnu-abi}} \
-              libxrandr-dev libxtst-dev libcups2-dev libasound2-dev
+              libxrandr-dev libxtst-dev libcups2-dev libasound2-dev libatspi2.0-dev libatk1.0-dev libglib2.0-dev libatk-bridge2.0-dev
           sudo update-alternatives --install /usr/bin/gcc gcc /usr/bin/gcc-${{ inputs.gcc-major-version }} 100 --slave /usr/bin/g++ g++ /usr/bin/g++-${{ inputs.gcc-major-version }}
 
       - name: 'Check cache for sysroot'
@@ -133,7 +133,7 @@ jobs:
           sudo debootstrap
           --arch=${{ matrix.debian-arch }}
           --verbose
-          --include=fakeroot,symlinks,build-essential,libx11-dev,libxext-dev,libxrender-dev,libxrandr-dev,libxtst-dev,libxt-dev,libcups2-dev,libfontconfig1-dev,libasound2-dev,libfreetype-dev,libpng-dev
+          --include=fakeroot,symlinks,build-essential,libx11-dev,libxext-dev,libxrender-dev,libxrandr-dev,libxtst-dev,libxt-dev,libcups2-dev,libfontconfig1-dev,libasound2-dev,libfreetype-dev,libpng-dev,libatspi2.0-dev,libatk1.0-dev,libglib2.0-dev,libatk-bridge2.0-dev
           --resolve-deps
           --variant=minbase
           ${{ matrix.debian-version }}

.github/workflows/build-linux.yml

@@ -111,7 +111,7 @@ jobs:
           fi
           sudo apt-get update
           sudo apt-get install --only-upgrade apt
-          sudo apt-get install gcc-${{ inputs.gcc-major-version }}${{ inputs.gcc-package-suffix }} g++-${{ inputs.gcc-major-version }}${{ inputs.gcc-package-suffix }} libxrandr-dev${{ steps.arch.outputs.suffix }} libxtst-dev${{ steps.arch.outputs.suffix }} libcups2-dev${{ steps.arch.outputs.suffix }} libasound2-dev${{ steps.arch.outputs.suffix }} ${{ inputs.apt-extra-packages }}
+          sudo apt-get install gcc-${{ inputs.gcc-major-version }}${{ inputs.gcc-package-suffix }} g++-${{ inputs.gcc-major-version }}${{ inputs.gcc-package-suffix }} libxrandr-dev${{ steps.arch.outputs.suffix }} libxtst-dev${{ steps.arch.outputs.suffix }} libcups2-dev${{ steps.arch.outputs.suffix }} libasound2-dev${{ steps.arch.outputs.suffix }} libatspi2.0-dev${{ steps.arch.outputs.suffix }} libatk1.0-dev${{ steps.arch.outputs.suffix }} libglib2.0-dev${{ steps.arch.outputs.suffix }} ${{ inputs.apt-extra-packages }}
           sudo update-alternatives --install /usr/bin/gcc gcc /usr/bin/gcc-${{ inputs.gcc-major-version }} 100 --slave /usr/bin/g++ g++ /usr/bin/g++-${{ inputs.gcc-major-version }}
 
       - name: 'Configure'

README.md

@@ -141,6 +141,15 @@ $ make images
 ```
 This will build the release configuration under `./build/linux-x86_64-server-release/`.
 
+#### Java ATK Wrapper
+
+To enable [Java ATK Wrapper](https://wiki.gnome.org/Accessibility/JavaAtkWrapper):
+1. Install the necessary libraries and headers with:
+```
+$ sudo apt-get install libatspi2.0-dev libatk1.0-dev libglib2.0-dev libatk-bridge2.0-dev
+```
+2. Run `configure` using `--enable-java-atk-wrapper`
+
 ### Windows
 <a name="build-windows"></a>
 Install the following:

make/autoconf/help.m4

@@ -119,6 +119,8 @@ apt_help() {
       PKGHANDLER_COMMAND="sudo apt-get install systemtap-sdt-dev" ;;
     capstone)
       PKGHANDLER_COMMAND="sudo apt-get install libcapstone-dev" ;;
+    atk)
+      PKGHANDLER_COMMAND="sudo apt-get install libatspi2.0-dev libatk1.0-dev libglib2.0-dev" ;;
   esac
 }
 

make/autoconf/jdk-options.m4

@@ -270,6 +270,28 @@ AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_OPTIONS],
     A11Y_JAWS_ANNOUNCING_ENABLED=false
   fi
   AC_SUBST(A11Y_JAWS_ANNOUNCING_ENABLED)
+
+  # Should we build support for Java ATK Wrapper?
+  if test "x$OPENJDK_TARGET_OS" = xlinux; then
+    AC_MSG_CHECKING([if Java ATK Wrapper support is enabled])
+
+    A11Y_JAVA_ATK_WRAPPER_ENABLED=false
+    AC_ARG_ENABLE(
+      [java-atk-wrapper],
+      [AS_HELP_STRING([--enable-java-atk-wrapper], [Set to enable the Java ATK Wrapper])],
+      [
+        if test "x$ENABLE_HEADLESS_ONLY" = xtrue; then
+          AC_MSG_WARN([--[enable|disable]-java-atk-wrapper[=*] flags are ignored for headless builds])
+        elif test "x$enableval" == xyes; then
+          A11Y_JAVA_ATK_WRAPPER_ENABLED=true
+        fi
+      ]
+    )
+    AC_MSG_RESULT([$A11Y_JAVA_ATK_WRAPPER_ENABLED])
+  else
+    A11Y_JAVA_ATK_WRAPPER_ENABLED=false
+  fi
+  AC_SUBST(A11Y_JAVA_ATK_WRAPPER_ENABLED)
 ])
 
 ###############################################################################

make/autoconf/lib-at-spi2-atk.m4

@@ -0,0 +1,70 @@
+################################################################################
+# Setup at-spi2-atk
+################################################################################
+AC_DEFUN_ONCE([LIB_SETUP_AT_SPI2_ATK],
+[
+  AC_ARG_WITH(at-spi2-atk, [AS_HELP_STRING([--with-at-spi2-atk],
+      [specify prefix directory for the at-spi2-atk package
+      (expecting the headers under PATH/include); required for atk-wrapper to work])])
+  AC_ARG_WITH(at-spi2-atk-include, [AS_HELP_STRING([--with-at-spi2-atk-include],
+      [specify directory for the at-spi2-atk include files])])
+  AC_ARG_WITH(at-spi2-atk-version, [AS_HELP_STRING([--with-at-spi2-atk-version],
+        [specify version for the at-spi2-atk package])])
+
+  if test "x$NEEDS_LIB_AT_SPI2_ATK" = xfalse || test "x${with_at_spi2_atk}" = xno || \
+      test "x${with_at_spi2_atk_include}" = xno; then
+    if (test "x${with_at_spi2_atk}" != x && test "x${with_at_spi2_atk}" != xno) || \
+        (test "x${with_at_spi2_atk_include}" != x && test "x${with_at_spi2_atk_include}" != xno); then
+      AC_MSG_WARN([[at-spi2-atk not used, so --with-at-spi2-atk[-*] is ignored]])
+    fi
+    AT_SPI2_ATK_CFLAGS=
+    AT_SPI2_ATK_LIBS=
+  else
+    AT_SPI2_ATK_FOUND=no
+    if test "x${with_at_spi2_atk}" != x && test "x${with_at_spi2_atk}" != xyes; then
+      AC_MSG_CHECKING([for at-spi2-atk header and library])
+      if test "x${with_at_spi2_atk_version}" != x && "x${with_at_spi2_atk_version}" != xyes; then
+        AT_SPI2_ATK_VERSION="${with_at_spi2_atk_version}"
+      else
+        AC_MSG_ERROR([Define at-spi2-atk package version using --with-at-spi2-atk-version if you use --with-at-spi2-atk option.])
+      fi
+      if test -s "${with_at_spi2_atk}/include/at-spi2-atk/2.0/atk-bridge.h"; then
+        AT_SPI2_ATK_CFLAGS="-I${with_at_spi2_atk}/include/at-spi2-atk/2.0"
+        AT_SPI2_ATK_LIBS="-L${with_at_spi2_atk}/lib -latk-bridge-2.0"
+        AT_SPI2_ATK_FOUND=yes
+        AC_MSG_RESULT([$AT_SPI2_ATK_FOUND])
+      else
+        AC_MSG_ERROR([Can't find '/include/at-spi2-atk/2.0/atk-bridge.h' under ${with_at_spi2_atk} given with the --with-at-spi2-atk option.])
+      fi
+    fi
+    if test "x${with_at_spi2_atk_include}" != x; then
+      AC_MSG_CHECKING([for at-spi2-atk headers])
+      if test "x${with_at_spi2_atk_version}" != x && "x${with_at_spi2_atk_version}" != xyes; then
+        AT_SPI2_ATK_VERSION="${with_at_spi2_atk_version}"
+      else
+        AC_MSG_ERROR([Define at-spi2-atk package version using --with-at-spi2-atk-version if you use --with-at-spi2-atk-include option.])
+      fi
+      if test -s "${with_at_spi2_atk_include}/at-spi2-atk/2.0/atk-bridge.h"; then
+        AT_SPI2_ATK_CFLAGS="-I${with_at_spi2_atk_include}/at-spi2-atk/2.0"
+        AT_SPI2_ATK_FOUND=yes
+        AC_MSG_RESULT([$AT_SPI2_ATK_FOUND])
+      else
+        AC_MSG_ERROR([Can't find 'include/at-spi2-atk-2.0/atk-bridge.h' under ${with_at_spi2_atk_include} given with the --with-at-spi2-atk-include option.])
+      fi
+    fi
+    if test "x$AT_SPI2_ATK_FOUND" = xno; then
+      # Are the at-spi2-atk headers installed in the default /usr/include location?
+      PKG_CHECK_MODULES([AT_SPI2_ATK], [atk-bridge-2.0],
+        [AT_SPI2_ATK_FOUND=yes; AT_SPI2_ATK_VERSION=$("$PKG_CONFIG" --modversion atk-bridge-2.0)],
+        [AT_SPI2_ATK_FOUND=no; break]
+      )
+    fi
+    if test "x$AT_SPI2_ATK_FOUND" = xno; then
+      HELP_MSG_MISSING_DEPENDENCY([at-spi2-atk])
+      AC_MSG_ERROR([Could not find at-spi2-atk! $HELP_MSG ])
+    fi
+  fi
+  AT_SPI2_ATK_CFLAGS="$AT_SPI2_ATK_CFLAGS -DATSPI_MAJOR_VERSION=$(echo $AT_SPI2_ATK_VERSION | cut -d. -f1) -DATSPI_MINOR_VERSION=$(echo $AT_SPI2_ATK_VERSION | cut -d. -f2) -DATSPI_MICRO_VERSION=$(echo $AT_SPI2_ATK_VERSION | cut -d. -f3)"
+  AC_SUBST(AT_SPI2_ATK_CFLAGS)
+  AC_SUBST(AT_SPI2_ATK_LIBS)
+])

make/autoconf/lib-atk.m4

@@ -0,0 +1,53 @@
+################################################################################
+# Setup atk
+################################################################################
+AC_DEFUN_ONCE([LIB_SETUP_ATK],
+[
+  AC_ARG_WITH(atk, [AS_HELP_STRING([--with-atk],
+      [specify prefix directory for the atk package
+      (expecting the headers under PATH/include); required for atk-wrapper to work])])
+  AC_ARG_WITH(atk-include, [AS_HELP_STRING([--with-atk-include],
+      [specify directory for the atk include files])])
+  if test "x$NEEDS_LIB_ATK" = xfalse || test "x${with_atk}" = xno || \
+      test "x${with_atk_include}" = xno; then
+    if (test "x${with_atk}" != x && test "x${with_atk}" != xno) || \
+        (test "x${with_atk_include}" != x && test "x${with_atk_include}" != xno); then
+      AC_MSG_WARN([[atk not used, so --with-atk[-*] is ignored]])
+    fi
+    ATK_CFLAGS=
+    ATK_LIBS=
+  else
+    ATK_FOUND=no
+    if test "x${with_atk}" != x && test "x${with_atk}" != xyes; then
+      AC_MSG_CHECKING([for atk header and library])
+      if test -s "${with_atk}/include/atk-1.0/atk/atk.h"; then
+        ATK_CFLAGS="-I${with_atk}/include/atk-1.0"
+        ATK_LIBS="-L${with_atk}/lib -latk-1.0"
+        ATK_FOUND=yes
+        AC_MSG_RESULT([$ATK_FOUND])
+      else
+        AC_MSG_ERROR([Can't find '/include/atk-1.0/atk/atk.h' under ${with_atk} given with the --with-atk option.])
+      fi
+    fi
+    if test "x${with_atk_include}" != x; then
+      AC_MSG_CHECKING([for atk headers])
+      if test -s "${with_atk_include}/atk-1.0/atk/atk.h"; then
+        ATK_CFLAGS="-I${with_atk_include}/atk-1.0"
+        ATK_FOUND=yes
+        AC_MSG_RESULT([$ATK_FOUND])
+      else
+        AC_MSG_ERROR([Can't find 'include/atk-1.0/atk/atk.h' under ${with_atk_include} given with the --with-atk-include option.])
+      fi
+    fi
+    if test "x$ATK_FOUND" = xno; then
+      # Are the atk headers installed in the default /usr/include location?
+      PKG_CHECK_MODULES([ATK], [atk], [ATK_FOUND=yes;], [ATK_FOUND=no; break])
+    fi
+    if test "x$ATK_FOUND" = xno; then
+      HELP_MSG_MISSING_DEPENDENCY([atk])
+      AC_MSG_ERROR([Could not find atk! $HELP_MSG ])
+    fi
+  fi
+  AC_SUBST(ATK_CFLAGS)
+  AC_SUBST(ATK_LIBS)
+])

make/autoconf/lib-glib.m4

@@ -0,0 +1,86 @@
+################################################################################
+# Setup glib
+################################################################################
+AC_DEFUN_ONCE([LIB_SETUP_GLIB],
+[
+  AC_ARG_WITH(glib, [AS_HELP_STRING([--with-glib],
+      [specify prefix directory for the glib package
+      (expecting the headers under PATH/include); required for atk-wrapper to work])])
+  AC_ARG_WITH(glib-include, [AS_HELP_STRING([--with-glib-include],
+      [specify directory for the glib include files])])
+  AC_ARG_WITH(glibconfig, [AS_HELP_STRING([--with-glibconfig],
+        [specify prefix directory for the glibconfig package
+        (expecting the headers under PATH/include); required for atk-wrapper to work])])
+  AC_ARG_WITH(glibconfig-include, [AS_HELP_STRING([--with-glibconfig-include],
+        [specify directory for the glibconfig include files])])
+
+  if test "x$NEEDS_LIB_GLIB" = xfalse || test "x${with_glib}" = xno || \
+      test "x${with_glib_include}" = xno || \
+      test "x${with_glibconfig}" = xno || test "x${with_glibconfig_include}" = xno; then
+    if (test "x${with_glib}" != x && test "x${with_glib}" != xno) || \
+        (test "x${with_glib_include}" != x && test "x${with_glib_include}" != xno) || \
+         (test "x${with_glibconfig}" != x && test "x${with_glibconfig}" != xno) || \
+          (test "x${with_glibconfig_include}" != x && test "x${with_glibconfig_include}" != xno); then
+      AC_MSG_WARN([[glib not used, so --with-glib[-*] and --with-glibconfig[-*] are ignored]])
+    fi
+    GLIB_CFLAGS=
+    GLIB_LIBS=
+    GLIBCONFIG_CFLAGS=
+  else
+    GLIB_FOUND=no
+    GLIBCONFIG_FOUND=no
+    GLIBCONFIG_CFLAGS=
+    if test "x${with_glib}" != x && test "x${with_glib}" != xyes; then
+      AC_MSG_CHECKING([for glib header and library])
+      if test -s "${with_glib}/include/glib-2.0/glib.h"; then
+        GLIB_CFLAGS="-I${with_glib}/include/glib-2.0"
+        GLIB_LIBS="-L${with_glib}/lib -lglib-2.0"
+        GLIB_FOUND=yes
+        AC_MSG_RESULT([$GLIB_FOUND])
+      else
+        AC_MSG_ERROR([Can't find '/include/glib-2.0/glib.h' under ${with_glib} given with the --with-glib option.])
+      fi
+    fi
+    if test "x${with_glib_include}" != x; then
+      AC_MSG_CHECKING([for glib headers])
+      if test -s "${with_glib_include}/glib-2.0/glib.h"; then
+        GLIB_CFLAGS="-I${with_glib_include}"
+        GLIB_FOUND=yes
+        AC_MSG_RESULT([$GLIB_FOUND])
+      else
+        AC_MSG_ERROR([Can't find '/include/glib-2.0/glib.h' under ${with_glib_include} given with the --with-glib-include option.])
+      fi
+    fi
+    if test "x${with_glibconfig}" != x && test "x${with_glibconfig}" != xyes; then
+      AC_MSG_CHECKING([for glibconfig header])
+      if test -s "${with_glibconfig}/include/glibconfig.h"; then
+        GLIBCONFIG_CFLAGS="-I${with_glibconfig}/include"
+        GLIBCONFIG_FOUND=yes
+        AC_MSG_RESULT([$GLIBCONFIG_FOUND])
+      else
+        AC_MSG_ERROR([Can't find '/include/glibconfig.h' under ${with_glibconfig} given with the --with-glibconfig option.])
+      fi
+    fi
+    if test "x${with_glibconfig_include}" != x; then
+      AC_MSG_CHECKING([for glibconfig headers])
+      if test -s "${with_glibconfig_include}/glibconfig.h"; then
+        GLIBCONFIG_CFLAGS="-I${with_glibconfig_include}"
+        GLIBCONFIG_FOUND=yes
+        AC_MSG_RESULT([$GLIBCONFIG_FOUND])
+      else
+        AC_MSG_ERROR([Can't find '/include/glibconfig.h' under ${with_glibconfig_include} given with the --with-glibconfig-include option.])
+      fi
+    fi
+    if test "x$GLIB_FOUND" = xno || test "x$GLIBCONFIG_FOUND" = xno; then
+      # Are the glib headers installed in the default /usr/include location?
+      PKG_CHECK_MODULES([GLIB], [glib-2.0], [GLIB_FOUND=yes; GLIBCONFIG_FOUND=yes], [GLIB_FOUND=no; GLIBCONFIG_FOUND=no; break])
+    fi
+    if test "x$GLIB_FOUND" = xno || test "x$GLIBCONFIG_FOUND" = xno; then
+      HELP_MSG_MISSING_DEPENDENCY([glib])
+      AC_MSG_ERROR([Could not find glib! $HELP_MSG])
+    fi
+  fi
+  GLIB_CFLAGS="$GLIB_CFLAGS $GLIBCONFIG_CFLAGS"
+  AC_SUBST(GLIB_CFLAGS)
+  AC_SUBST(GLIB_LIBS)
+])

make/autoconf/lib-gobject.m4

@@ -0,0 +1,58 @@
+################################################################################
+# Setup gobject
+################################################################################
+AC_DEFUN_ONCE([LIB_SETUP_GOBJECT],
+[
+  AC_ARG_WITH(gobject, [AS_HELP_STRING([--with-gobject],
+      [specify prefix directory for the gobject package
+      (expecting the headers under PATH/include); required for atk-wrapper to work])])
+  AC_ARG_WITH(gobject-include, [AS_HELP_STRING([--with-gobject-include],
+      [specify directory for the gobject include files])])
+
+  if test "x$NEEDS_LIB_GOBJECT" = xfalse || test "x${with_gobject}" = xno || \
+      test "x${with_gobject_include}" = xno; then
+    if (test "x${with_gobject}" != x && test "x${with_gobject}" != xno) || \
+        (test "x${with_gobject_include}" != x && test "x${with_gobject_include}" != xno); then
+      AC_MSG_WARN([[gobject not used, so --with-gobject[-*] is ignored]])
+    fi
+    GOBJECT_CFLAGS=
+    GOBJECT_LIBS=
+  else
+    GOBJECT_FOUND=no
+
+    if test "x${with_gobject}" != x && test "x${with_gobject}" != xyes; then
+      AC_MSG_CHECKING([for gobject header and library])
+      if test -s "${with_gobject}/include/glib-2.0/gobject/gobject.h"; then
+        GOBJECT_CFLAGS="-I${with_gobject}/include/glib-2.0/gobject"
+        GOBJECT_LIBS="-L${with_gobject}/lib -lgobject-2.0"
+        GOBJECT_FOUND=yes
+        AC_MSG_RESULT([$GOBJECT_FOUND])
+      else
+        AC_MSG_ERROR([Can't find '/include/glib-2.0/gobject/gobject.h' under ${with_gobject} given with the --with-gobject option.])
+      fi
+    fi
+    if test "x${with_gobject_include}" != x; then
+      AC_MSG_CHECKING([for gobject headers])
+      if test -s "${with_gobject_include}/glib-2.0/gobject/gobject.h"; then
+        GOBJECT_CFLAGS="-I${with_gobject_include}/glib-2.0/gobject"
+        GOBJECT_FOUND=yes
+        AC_MSG_RESULT([$GOBJECT_FOUND])
+      else
+        AC_MSG_ERROR([Can't find '/include/glib-2.0/gobject/gobject.h' under ${with_gobject_include} given with the --with-gobject-include option.])
+      fi
+    fi
+    if test "x$GOBJECT_FOUND" = xno; then
+      # Are the gobject headers installed in the default /usr/include location?
+      PKG_CHECK_MODULES([GOBJECT], [gobject-2.0],
+        [ GOBJECT_FOUND=yes;],
+        [ GOBJECT_FOUND=no; break ]
+      )
+    fi
+    if test "x$GOBJECT_FOUND" = xno; then
+      HELP_MSG_MISSING_DEPENDENCY([gobject])
+      AC_MSG_ERROR([Could not find gobject! $HELP_MSG ])
+    fi
+  fi
+  AC_SUBST(GOBJECT_CFLAGS)
+  AC_SUBST(GOBJECT_LIBS)
+])

make/autoconf/libraries.m4

@@ -39,6 +39,10 @@ m4_include([lib-nvdacontrollerclient.m4])
 m4_include([lib-wayland.m4])
 m4_include([lib-dbus.m4])
 m4_include([lib-tests.m4])
+m4_include([lib-atk.m4])
+m4_include([lib-at-spi2-atk.m4])
+m4_include([lib-glib.m4])
+m4_include([lib-gobject.m4])
 
 ################################################################################
 # Determine which libraries are needed for this configuration
@@ -112,6 +116,19 @@ AC_DEFUN_ONCE([LIB_DETERMINE_DEPENDENCIES],
   else
     NEEDS_LIB_NVDACONTROLLERCLIENT=false
   fi
+
+  # Check if atk, at-spi2-atk, glib, gobject is needed
+  if test "x$A11Y_JAVA_ATK_WRAPPER_ENABLED" = xtrue; then
+    NEEDS_LIB_ATK=true
+    NEEDS_LIB_AT_SPI2_ATK=true
+    NEEDS_LIB_GLIB=true
+    NEEDS_LIB_GOBJECT=true
+  else
+    NEEDS_LIB_ATK=false
+    NEEDS_LIB_AT_SPI2_ATK=false
+    NEEDS_LIB_GLIB=false
+    NEEDS_LIB_GOBJECT=false
+  fi
 ])
 
 ################################################################################
@@ -185,6 +202,12 @@ AC_DEFUN_ONCE([LIB_SETUP_LIBRARIES],
     BASIC_JVM_LIBS="$BASIC_JVM_LIBS -lrt"
   fi
 
+  # libraries for Java ATK Wrapper
+  LIB_SETUP_AT_SPI2_ATK
+  LIB_SETUP_ATK
+  LIB_SETUP_GLIB
+  LIB_SETUP_GOBJECT
+
   # perfstat lib
   if test "x$OPENJDK_TARGET_OS" = xaix; then
     BASIC_JVM_LIBS="$BASIC_JVM_LIBS -lperfstat"