Initial commit

dev/main.tf

@@ -0,0 +1,3 @@
+module "dev" {
+    source = "../modules/blog"
+}

modules/blog/main.tf

@@ -0,0 +1,94 @@
+data "aws_ami" "app_ami" {
+  most_recent = true
+
+  filter {
+    name   = "name"
+    values = [var.ami_filter.name]
+  }
+
+  filter {
+    name   = "virtualization-type"
+    values = ["hvm"]
+  }
+
+  owners = [var.ami_filter.owner] # Bitnami
+}
+
+
+module "blog_vpc" {
+  source = "terraform-aws-modules/vpc/aws"
+
+  name = var.environment.name
+  cidr = "${var.environment.network_prefix}.0.0/16"
+
+  azs             = ["us-west-2a","us-west-2b","us-west-2c"]
+  public_subnets  = ["${var.environment.network_prefix}.101.0/24", "${var.environment.network_prefix}.102.0/24", "${var.environment.network_prefix}.103.0/24"]
+
+
+  tags = {
+    Terraform = "true"
+    Environment = var.environment.name
+  }
+}
+
+
+module "blog_autoscaling" {
+  source  = "terraform-aws-modules/autoscaling/aws"
+  version = "6.5.2"
+
+  name = "blog"
+
+  min_size            = var.asg_min
+  max_size            = var.asg_max
+  vpc_zone_identifier = module.blog_vpc.public_subnets
+  target_group_arns   = module.blog_alb.target_group_arns
+  security_groups     = [module.blog_sg.security_group_id]
+  instance_type       = var.instance_type
+  image_id            = data.aws_ami.app_ami.id
+}
+
+module "blog_alb" {
+  source  = "terraform-aws-modules/alb/aws"
+  version = "~> 6.0"
+
+  name = "blog-alb"
+
+  load_balancer_type = "application"
+
+  vpc_id             = module.blog_vpc.vpc_id
+  subnets            = module.blog_vpc.public_subnets
+  security_groups    = [module.blog_sg.security_group_id]
+
+  target_groups = [
+    {
+      name_prefix      = "blog-"
+      backend_protocol = "HTTP"
+      backend_port     = 80
+      target_type      = "instance"
+    }
+  ]
+
+  http_tcp_listeners = [
+    {
+      port               = 80
+      protocol           = "HTTP"
+      target_group_index = 0
+    }
+  ]
+
+  tags = {
+    Environment = "dev"
+  }
+}
+
+module "blog_sg" {
+  source  = "terraform-aws-modules/security-group/aws"
+  version = "4.13.0"
+
+  vpc_id  = module.blog_vpc.vpc_id
+  name    = "blog"
+  ingress_rules = ["https-443-tcp","http-80-tcp"]
+  ingress_cidr_blocks = ["0.0.0.0/0"]
+  egress_rules = ["all-all"]
+  egress_cidr_blocks = ["0.0.0.0/0"]
+}

modules/blog/outputs.tf

@@ -0,0 +1,3 @@
+output "environmental_url" {
+  value = module.blog_alb.lb_dns_name
+}

modules/blog/variables.tf

@@ -0,0 +1,42 @@
+variable "instance_type" {
+  description = "Type of EC2 instance to provision"
+  default     = "t3.nano"
+}
+
+variable "ami_filter" {
+  description = "Name filter and owner for AMI"
+
+  type = object({
+    name = string
+    owner = string
+  })
+
+  default = {
+    name  = "bitnami-tomcat-*-x86_64-hvm-ebs-nami"
+    owner = "979382823631"
+  }
+}
+
+variable "environment" {
+  description = "Development Environment"
+
+  type = object ({
+    name = string
+    network_prefix = string
+  })
+
+  default = {
+    name = "dev"
+    network_prefix = "10.0"
+  }
+}
+
+variable "asg_min" {
+  description = "Minimum number of instance in the ASG"
+  default     = 1
+}
+
+variable "asg_max" {
+  description = "Maximum number of instance in the ASG"
+  default     = 2
+}

qa/main.tf

@@ -0,0 +1,11 @@
+module "qa" {
+    source = "../modules/blog"
+
+    environment = {
+        name           = "qa"
+        network_prefix = "10.1"
+    }
+
+    asg_min = 1
+    asg_max = 1
+}

qa/output.tf

@@ -0,0 +1,3 @@
+output "environmental_url" {
+    value = module.qa.environmental_url
+}

qa/providers.tf

@@ -0,0 +1,11 @@
+terraform {
+  required_providers {
+    aws = {
+      source  = "hashicorp/aws"
+    }
+  }
+}
+
+provider "aws" {
+  region  = "us-west-2"
+}