build: Fix issue with missing TBB::tbb target in pxrConfig.cmake

Change 2369739 updated USD to specify library dependencies on TBB
with the more modern TBB::tbb target. This caused the targets in
USD's package config file to specify TBB::tbb as an interface link
library instead of the absolute path to the .so/.dll.

This caused problems when trying to link other cmake-based projects
to the USD package for USD builds using legacy TBB. In this case,
the TBB::tbb target (typically) is created by USD internally and
isn't available to clients, which caused "target was not found"
errors.

This fix recreates the TBB::tbb target in pxrConfig.cmake to ensure
its available in the above case. This should yield the same behavior
as before the change mentioned above.

(Internal change: 2372031)

Author: sunyab

pxr/CMakeLists.txt

@@ -23,6 +23,40 @@ pxr_core_epilogue()
 
 export(PACKAGE pxr)
 
+# XXX:
+# Libraries specify the TBB::tbb target to link against TBB. This target
+# is either imported from the package config file that is installed with
+# oneTBB (and is optionally installed with TBB), or it is created by the
+# USD build as part of the FindTBB cmake module.
+#
+# The TBB::tbb target must be available when a client builds against USD
+# using its pxrConfig.cmake package config file. In the former case above,
+# clients can use the same package config file from TBB they used when
+# building USD itself. But in the latter case, USD itself needs to export
+# the TBB::tbb target it created.
+#
+# Typically a target would be exported using `export(TARGETS ...)` but
+# this doesn't work for TBB::tbb because it's an imported target. So we
+# manually set up this target in pxrConfig.cmake and copy over the
+# relevant properties that are set up in FindTBB.cmake. These properties
+# specify the TBB library that USD was actually built against and don't
+# include other configurations.
+#
+# This can all go away when support for TBB is dropped in favor of oneTBB
+# and we solely rely on its package config file.
+foreach(property IN ITEMS
+    INTERFACE_INCLUDE_DIRECTORIES
+    INTERFACE_COMPILE_DEFINITIONS
+    INTERFACE_LINK_DIRECTORIES
+    IMPORTED_IMPLIB
+    IMPORTED_LOCATION)
+
+    get_target_property(value TBB::tbb ${property})
+    if (value)
+        set(tbb_${property} "${value}")
+    endif()
+endforeach()
+
 configure_file(pxrConfig.cmake.in
   "${PROJECT_BINARY_DIR}/pxrConfig.cmake" @ONLY)
 install(FILES

pxr/pxrConfig.cmake.in

@@ -54,6 +54,20 @@ if (NOT DEFINED PXR_FIND_TBB_IN_CONFIG)
 endif()
 if (PXR_FIND_TBB_IN_CONFIG)
     find_dependency(TBB @TBB_VERSION@ CONFIG)
+else()
+    add_library(TBB::tbb SHARED IMPORTED)
+
+    macro(_add_property name value)
+        if (NOT "${value}" STREQUAL "")
+            set_target_properties(TBB::tbb PROPERTIES ${name} "${value}")
+        endif()
+    endmacro()
+
+    _add_property(INTERFACE_INCLUDE_DIRECTORIES "@tbb_INTERFACE_INCLUDE_DIRECTORIES@")
+    _add_property(INTERFACE_COMPILE_DEFINITIONS "@tbb_INTERFACE_COMPILE_DEFINITIONS@")
+    _add_property(INTERFACE_LINK_DIRECTORIES "@tbb_INTERFACE_LINK_DIRECTORIES@")
+    _add_property(IMPORTED_IMPLIB "@tbb_IMPORTED_IMPLIB@")
+    _add_property(IMPORTED_LOCATION "@tbb_IMPORTED_LOCATION@")
 endif()
 
 if (NOT DEFINED PXR_FIND_OPENSUBDIV_IN_CONFIG)