[CMake] Add code for finding clang-format and applying it to the code base. (#493)

Author: OmniBlade

CMakeLists.txt

@@ -33,6 +33,10 @@ endif()
 # Top level project, doesn't really affect anything.
 project(genzh LANGUAGES C CXX)
 
+# Set up a format target to do automated clang format checking.
+find_package(ClangFormat)
+include(ClangFormat)
+
 # This file handles extra settings wanted/needed for different compilers.
 include(cmake/compilers.cmake)
 

cmake/ClangFormat.cmake

@@ -0,0 +1,31 @@
+if(CLANG_FORMAT_FOUND)
+    if(CLANG_FORMAT_VERSION VERSION_LESS "19.0.0")
+        message(WARNING "clang-format ${CLANG_FORMAT_VERSION} is older than 19.0.0, formatting may yield unexpected results")
+    elseif(CLANG_FORMAT_VERSION VERSION_GREATER "19.1.1")
+        message(WARNING "clang-format ${CLANG_FORMAT_VERSION} is newer than 19.1.4, formatting may yield unexpected results")
+    else()
+        message(STATUS "Found clang-format ${CLANG_FORMAT_VERSION}, 'format' target enabled")
+    endif()
+
+    set(GLOB_PATTERNS
+        Generals/*.c
+        Generals/*.cpp
+        Generals/*.h
+        GeneralsMD/*.c
+        GeneralsMD/*.cpp
+        GeneralsMD/*.h
+    )
+
+    file(GLOB_RECURSE ALL_SOURCE_FILES RELATIVE ${CMAKE_SOURCE_DIR} ${GLOB_PATTERNS})
+
+    add_custom_target(format)
+    foreach(SOURCE_FILE ${ALL_SOURCE_FILES})
+        add_custom_command(
+            TARGET format
+            PRE_BUILD
+            COMMAND ${CLANG_FORMAT_EXECUTABLE} -style=file -i --verbose \"${SOURCE_FILE}\"
+            WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
+    endforeach()
+else()
+    message(WARNING "clang-format not found, 'format' target unavailable")
+endif()

cmake/FindClangFormat.cmake

@@ -0,0 +1,29 @@
+find_program(CLANG_FORMAT_EXECUTABLE
+             NAMES clang-format-19
+                   clang-format
+             DOC "clang-format executable")
+mark_as_advanced(CLANG_FORMAT_EXECUTABLE)
+
+if(CLANG_FORMAT_EXECUTABLE)
+    if(NOT CLANG_FORMAT_FOUND)
+        execute_process(COMMAND ${CLANG_FORMAT_EXECUTABLE} -version
+                        OUTPUT_VARIABLE clang_format_version
+                        ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
+
+        if(clang_format_version MATCHES "^.*clang-format version .*")
+            string(REGEX
+                   REPLACE ".*clang-format version ([.0-9]+).*"
+                           "\\1"
+                           clang_format_version_parsed
+                           "${clang_format_version}")
+
+            set(CLANG_FORMAT_VERSION ${clang_format_version_parsed} CACHE INTERNAL "clang-format executable version")
+            set(CLANG_FORMAT_FOUND TRUE CACHE INTERNAL "clang-format executable found")
+        endif()
+
+        unset(clang_format_version)
+        unset(clang_format_version_parsed)
+    endif()
+else()
+    set(CLANG_FORMAT_FOUND FALSE CACHE INTERNAL "clang-format executable found")
+endif()