mlir-aie/aie_runtime_lib/CMakeLists.txt at b0820314fa894fd244e02a3a443c4237b3438da4 · Xilinx/mlir-aie · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
#
# This file is licensed under the Apache License v2.0 with LLVM Exceptions.
# See https://llvm.org/LICENSE.txt for license information.
# SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
#
# (c) Copyright 2021 Xilinx Inc.

# Stuff into the build area:
add_custom_target(aie-runtime-libs ALL)

function(add_aie_runtime_libs arch)
  # Precompile the intrinsic wrappers.
  if(DEFINED VITIS_AIETOOLS_DIR)
    string(TOLOWER ${arch} aiearch)
    add_custom_target(${arch}_chess_intrinsic_wrapper ALL DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/chess_intrinsic_wrapper.ll)
    add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/chess_intrinsic_wrapper.ll
            COMMAND ${PROJECT_BINARY_DIR}/bin/xchesscc_wrapper ${arch}
            -aietools ${AIETOOLS_DIR}
            -c ${CMAKE_CURRENT_SOURCE_DIR}/chess_intrinsic_wrapper.cpp
            -d # Disassemble output
            -f # Use LLVM frontend
            +f # ... and emit LLVMIR
            -o ${CMAKE_CURRENT_BINARY_DIR}/chess_intrinsic_wrapper.ll
            COMMAND sed -i s/^target.*//
            ${CMAKE_CURRENT_BINARY_DIR}/chess_intrinsic_wrapper.ll
            DEPENDS
            xchesscc_wrapper
            ${CMAKE_CURRENT_SOURCE_DIR}/chess_intrinsic_wrapper.cpp)
    install(FILES ${CMAKE_CURRENT_BINARY_DIR}/chess_intrinsic_wrapper.ll DESTINATION ${CMAKE_INSTALL_PREFIX}/aie_runtime_lib/${arch})
    add_dependencies(aie-runtime-libs ${arch}_chess_intrinsic_wrapper)
  endif()

  set(INSTALLS
      lut_based_ops.cpp
      lut_based_ops.h
      vec_math.h)

  foreach(file ${INSTALLS})
      add_custom_target(aie-copy-${arch}-runtime-libs-${file} ALL DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${file})
      add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${file}
                      COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/${file}
                      ${CMAKE_CURRENT_BINARY_DIR}/${file}
                      DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${file})
      add_dependencies(aie-runtime-libs aie-copy-${arch}-runtime-libs-${file})
  endforeach()

  install(FILES ${INSTALLS} DESTINATION ${CMAKE_INSTALL_PREFIX}/aie_runtime_lib/${arch})

  add_subdirectory(aiesim)

endfunction()

# Compile AIE runtime libs if component found
if(AIETools_AIE_FOUND)
  add_subdirectory(AIE)
endif()
if(AIETools_AIE2_FOUND)
  add_subdirectory(AIE2)
endif()
if(AIETools_AIE2P_FOUND)
  add_subdirectory(AIE2P)
endif()

# Install and copy aie_objectfifo.h unconditionally (no AIETools dependency)
foreach(arch AIE2 AIE2P)
  if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${arch}/aie_objectfifo.h)
    install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/${arch}/aie_objectfifo.h
            DESTINATION ${CMAKE_INSTALL_PREFIX}/aie_runtime_lib/${arch})
    add_custom_target(aie-copy-${arch}-runtime-libs-aie_objectfifo.h ALL
                      DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${arch}/aie_objectfifo.h)
    add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${arch}/aie_objectfifo.h
                       COMMAND ${CMAKE_COMMAND} -E copy
                       ${CMAKE_CURRENT_SOURCE_DIR}/${arch}/aie_objectfifo.h
                       ${CMAKE_CURRENT_BINARY_DIR}/${arch}/aie_objectfifo.h
                       DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${arch}/aie_objectfifo.h)
    add_dependencies(aie-runtime-libs aie-copy-${arch}-runtime-libs-aie_objectfifo.h)
  endif()
endforeach()