feat : more tracking in AccessManagerEnumerable

src/access/AccessManagerEnumerable.sol

@@ -12,16 +12,48 @@ import {IAccessManagerEnumerable} from 'src/access/interfaces/IAccessManagerEnum
 contract AccessManagerEnumerable is AccessManager, IAccessManagerEnumerable {
   using EnumerableSet for EnumerableSet.AddressSet;
   using EnumerableSet for EnumerableSet.Bytes32Set;
+  using EnumerableSet for EnumerableSet.UintSet;
+
+  /// @dev Set of all role identifiers.
+  EnumerableSet.UintSet private _rolesSet;
 
   /// @dev Map of role identifiers to their respective member sets.
   mapping(uint64 roleId => EnumerableSet.AddressSet) private _roleMembers;
 
+  /// @dev Map of role identifiers to their respective target contract addresses.
+  mapping(uint64 roleId => EnumerableSet.AddressSet) private _roleTargets;
+
+  /// @dev Map of target contract addresses to their current role identifiers.
+  mapping(address target => uint64 roleId) private _targetRoles;
+
   /// @dev Map of role identifiers and target contract addresses to their respective set of function selectors.
   mapping(uint64 roleId => mapping(address target => EnumerableSet.Bytes32Set))
     private _roleTargetFunctions;
 
+  /// @dev Constructor.
+  /// @param initialAdmin_ The address of the initial admin.
   constructor(address initialAdmin_) AccessManager(initialAdmin_) {}
 
+  /// @inheritdoc IAccessManagerEnumerable
+  function getRole(uint256 index) external view returns (uint64) {
+    return uint64(_rolesSet.at(index));
+  }
+
+  /// @inheritdoc IAccessManagerEnumerable
+  function getRoleCount() external view returns (uint256) {
+    return _rolesSet.length();
+  }
+
+  /// @inheritdoc IAccessManagerEnumerable
+  function getRoles(uint256 start, uint256 end) external view returns (uint64[] memory) {
+    uint256[] memory listedRoles = _rolesSet.values(start, end);
+    uint64[] memory roles;
+    assembly ('memory-safe') {
+      roles := listedRoles
+    }
+    return roles;
+  }
+
   /// @inheritdoc IAccessManagerEnumerable
   function getRoleMember(uint64 roleId, uint256 index) external view returns (address) {
     return _roleMembers[roleId].at(index);
@@ -41,6 +73,25 @@ contract AccessManagerEnumerable is AccessManager, IAccessManagerEnumerable {
     return _roleMembers[roleId].values(start, end);
   }
 
+  /// @inheritdoc IAccessManagerEnumerable
+  function getRoleTarget(uint64 roleId, uint256 index) external view returns (address) {
+    return _roleTargets[roleId].at(index);
+  }
+
+  /// @inheritdoc IAccessManagerEnumerable
+  function getRoleTargetCount(uint64 roleId) external view returns (uint256) {
+    return _roleTargets[roleId].length();
+  }
+
+  /// @inheritdoc IAccessManagerEnumerable
+  function getRoleTargets(
+    uint64 roleId,
+    uint256 start,
+    uint256 end
+  ) external view returns (address[] memory) {
+    return _roleTargets[roleId].values(start, end);
+  }
+
   /// @inheritdoc IAccessManagerEnumerable
   function getRoleTargetFunction(
     uint64 roleId,
@@ -73,7 +124,39 @@ contract AccessManagerEnumerable is AccessManager, IAccessManagerEnumerable {
     return targetFunctionSelectors;
   }
 
-  /// @dev Override AccessManager `_grantRole` function to track role members.
+  /// @dev Tracks all role identifiers when a new role is created.
+  function _trackRole(uint64 roleId) internal {
+    _rolesSet.add(uint256(roleId));
+  }
+
+  /// @dev Tracks all targets where a selector was assigned to a role.
+  function _trackRoleTarget(uint64 roleId, address target) internal {
+    uint64 oldRole = _targetRoles[target];
+    if (oldRole == roleId) {
+      return;
+    }
+    if (oldRole != ADMIN_ROLE && _roleTargetFunctions[oldRole][target].length() == 0) {
+      _roleTargets[oldRole].remove(target);
+    }
+    if (roleId != ADMIN_ROLE) {
+      _roleTargets[roleId].add(target);
+    }
+    _targetRoles[target] = roleId;
+  }
+
+  /// @dev Override AccessManager `_setRoleAdmin` function to track created roles.
+  function _setRoleAdmin(uint64 roleId, uint64 admin) internal override {
+    _trackRole(roleId);
+    super._setRoleAdmin(roleId, admin);
+  }
+
+  /// @dev Override AccessManager `_setRoleGuardian` function to track created roles.
+  function _setRoleGuardian(uint64 roleId, uint64 guardian) internal override {
+    _trackRole(roleId);
+    super._setRoleGuardian(roleId, guardian);
+  }
+
+  /// @dev Override AccessManager `_grantRole` function to track roles' membership.
   function _grantRole(
     uint64 roleId,
     address account,
@@ -82,12 +165,13 @@ contract AccessManagerEnumerable is AccessManager, IAccessManagerEnumerable {
   ) internal override returns (bool) {
     bool granted = super._grantRole(roleId, account, grantDelay, executionDelay);
     if (granted) {
+      _trackRole(roleId);
       _roleMembers[roleId].add(account);
     }
     return granted;
   }
 
-  /// @dev Override AccessManager `_revokeRole` function to remove from tracked role members.
+  /// @dev Override AccessManager `_revokeRole` function to remove from tracked roles' membership.
   function _revokeRole(uint64 roleId, address account) internal override returns (bool) {
     bool revoked = super._revokeRole(roleId, account);
     if (revoked) {
@@ -110,5 +194,7 @@ contract AccessManagerEnumerable is AccessManager, IAccessManagerEnumerable {
     if (roleId != ADMIN_ROLE) {
       _roleTargetFunctions[roleId][target].add(bytes32(selector));
     }
+    // also track the target under the role (will be added if not already present)
+    _trackRoleTarget(roleId, target);
   }
 }

src/access/interfaces/IAccessManagerEnumerable.sol

@@ -8,6 +8,22 @@ import {IAccessManager} from 'src/dependencies/openzeppelin/IAccessManager.sol';
 /// @author Aave Labs
 /// @notice Interface for AccessManagerEnumerable extension.
 interface IAccessManagerEnumerable is IAccessManager {
+  /// @notice Returns the indentifier of the role at a specified index.
+  /// @param index The index in the role list.
+  /// @return The identifier of the role.
+  function getRole(uint256 index) external view returns (uint64);
+
+  /// @notice Returns the total number of existing roles.
+  /// @dev Does not account for the built-in `PUBLIC_ROLE` role.
+  /// @return The number of roles.
+  function getRoleCount() external view returns (uint256);
+
+  /// @notice Returns the list of role identifiers between the specified indexes.
+  /// @param start The starting index for the role list.
+  /// @param end The ending index for the role list.
+  /// @return The list of role identifiers.
+  function getRoles(uint256 start, uint256 end) external view returns (uint64[] memory);
+
   /// @notice Returns the address of the role member at a specified index.
   /// @param roleId The identifier of the role.
   /// @param index The index in the role member list.
@@ -19,7 +35,7 @@ interface IAccessManagerEnumerable is IAccessManager {
   /// @return The number of members for the role.
   function getRoleMemberCount(uint64 roleId) external view returns (uint256);
 
-  /// @notice Returns the list of members for a specified role.
+  /// @notice Returns the list of members for a specified role between the specified indexes.
   /// @param roleId The identifier of the role.
   /// @param start The starting index for the member list.
   /// @param end The ending index for the member list.
@@ -30,6 +46,28 @@ interface IAccessManagerEnumerable is IAccessManager {
     uint256 end
   ) external view returns (address[] memory);
 
+  /// @notice Returns the address of the target contract for a specified role and index.
+  /// @param roleId The identifier of the role.
+  /// @param index The index in the role target list.
+  /// @return The address of the target contract.
+  function getRoleTarget(uint64 roleId, uint256 index) external view returns (address);
+
+  /// @notice Returns the number of targets for a specified role.
+  /// @param roleId The identifier of the role.
+  /// @return The number of targets for the role.
+  function getRoleTargetCount(uint64 roleId) external view returns (uint256);
+
+  /// @notice Returns the list of targets for a specified role between the specified indexes.
+  /// @param roleId The identifier of the role.
+  /// @param start The starting index for the role target list.
+  /// @param end The ending index for the role target list.
+  /// @return The list of targets for the role.
+  function getRoleTargets(
+    uint64 roleId,
+    uint256 start,
+    uint256 end
+  ) external view returns (address[] memory);
+
   /// @notice Returns the function selector assigned to a given role at the specified index.
   /// @param roleId The identifier of the role.
   /// @param target The address of the target contract.