Irritants (Smoke) - New Component

.hemtt/launch.toml

@@ -3,6 +3,12 @@ workshop = [
     "450814997", # CBA_A3
 ]
 
+[adt]
+extends = "default"
+workshop = [
+    "3499977893", # ADT
+]
+
 [rhs]
 extends = "default"
 workshop = [
@@ -27,10 +33,9 @@ workshop = [
 ]
 
 [wardrobe]
-extends = "default"
+extends = "adt"
 mission = "Wardrobe.VR"
 workshop = [
-    "3499977893", # Advanced Developer Tools
     "1779063631", # ZEN
 #   "751965892",  # ACRE
 #   "623475643",  # eden enhanced

addons/smoke/$PBOPREFIX$

@@ -0,0 +1 @@
+z\ace\addons\smoke

addons/smoke/ACE_Arsenal_Stats.hpp

@@ -0,0 +1,20 @@
+class EGVAR(arsenal,stats) {
+    class statBase;
+    class GVAR(breathing_protection): statBase {
+        scope = 2;
+        displayName = CSTRING(statBreatingProtection);
+        showBar = 1;
+        condition = QUOTE(getNumber (_this select 1 >> QQGVAR(Breathing_Protection)) > 0);
+        barStatement = QUOTE(getNumber (_this select 1 >> QQGVAR(Breathing_Protection)));
+        tabs[] = {{7}, {}};
+    };
+
+    class GVAR(eyes_protection): statBase {
+        scope = 2;
+        displayName = CSTRING(statEyesProtection);
+        showBar = 1;
+        condition = QUOTE(getNumber (_this select 1 >> QQGVAR(Eyes_Protection)) > 0);
+        barStatement = QUOTE(getNumber (_this select 1 >> QQGVAR(Eyes_Protection)));
+        tabs[] = {{7}, {}};
+    };
+};

addons/smoke/CfgEventHandlers.hpp

@@ -0,0 +1,15 @@
+class Extended_PreStart_EventHandlers {
+    class ADDON {
+        init = QUOTE(call COMPILE_FILE(XEH_preStart));
+    };
+};
+class Extended_PreInit_EventHandlers {
+    class ADDON {
+        init = QUOTE(call COMPILE_FILE(XEH_preInit));
+    };
+};
+class Extended_PostInit_EventHandlers {
+    class ADDON {
+        init = QUOTE(call COMPILE_FILE(XEH_postInit));
+    };
+};

addons/smoke/CfgGlasses.hpp

@@ -0,0 +1,53 @@
+class CfgGlasses {
+    class None;
+
+    class G_AirPurifyingRespirator_01_base_F: None {
+        GVAR(Eyes_Protection) = 1;
+        GVAR(Breathing_Protection) = 1;
+    };
+
+    class G_Balaclava_blk: None {
+        GVAR(Breathing_Protection) = 0.2;
+    };
+    class G_Balaclava_combat: G_Balaclava_blk {
+        GVAR(Eyes_Protection) = 1;
+    };
+    class G_Balaclava_lowprofile: G_Balaclava_blk {
+        GVAR(Eyes_Protection) = 1;
+    };
+
+    class G_Combat: None {
+        GVAR(Eyes_Protection) = 1;
+    };
+    class G_Lowprofile: None {
+        GVAR(Eyes_Protection) = 1;
+    };
+
+    class G_RegulatorMask_base_F: None {
+        GVAR(Eyes_Protection) = 1;
+        GVAR(Breathing_Protection) = 1;
+    };
+
+    class G_Respirator_base_F: None {
+        GVAR(Breathing_Protection) = 0.8;
+    };
+
+    class G_EyeProtectors_base_F: None {
+        GVAR(Eyes_Protection) = 0.2;
+    };
+
+    class G_Balaclava_TI_blk_F: None {
+        GVAR(Breathing_Protection) = 0.4;
+    };
+    class G_Balaclava_TI_G_blk_F: G_Balaclava_TI_blk_F {
+        GVAR(Eyes_Protection) = 1;
+    };
+    class G_Balaclava_TI_tna_F;
+    class G_Balaclava_TI_G_tna_F: G_Balaclava_TI_tna_F {
+        GVAR(Eyes_Protection) = 1;
+    };
+
+    class G_Blindfold_01_base_F: None {
+        GVAR(Eyes_Protection) = 0.6;
+    };
+};

addons/smoke/XEH_PREP.hpp

@@ -0,0 +1,2 @@
+PREP(isInSmoke);
+PREP(pfh);

addons/smoke/XEH_postInit.sqf

@@ -0,0 +1,22 @@
+#include "script_component.hpp"
+
+GVAR(ppHandleDynamicBlur) = ppEffectCreate ["DynamicBlur", 400];
+GVAR(ppHandleColorCorrections) = ppEffectCreate ["ColorCorrections", 1500];
+GVAR(ppHandleDynamicBlur) ppEffectEnable GVAR(enabled);
+GVAR(ppHandleColorCorrections) ppEffectEnable GVAR(enabled);
+
+if (GVAR(enabled)) then {
+    GVAR(pfh) = [{
+        [ace_player] call FUNC(pfh);
+    }] call CBA_fnc_addPerFrameHandler;
+};
+
+["loadout", {
+    params ["_unit"];
+    if !(local _unit) exitWith {};
+    private _config = configFile >> "CfgGlasses" >> goggles _unit;
+    private _breathing = getNumber (_config >> QGVAR(Breathing_Protection));
+    _unit setVariable [QGVAR(breathingProtection), _breathing, true];
+    private _eyes = getNumber (_config >> QGVAR(Eyes_Protection));
+    _unit setVariable [QGVAR(eyesProtection), _eyes, true];
+}, true] call CBA_fnc_addPlayerEventHandler;

addons/smoke/XEH_preInit.sqf

@@ -0,0 +1,11 @@
+#include "script_component.hpp"
+
+ADDON = false;
+
+#include "XEH_PREP.hpp"
+
+#include "initSettings.inc.sqf"
+
+GVAR(pfh) = -1;
+
+ADDON = true;

addons/smoke/XEH_preStart.sqf

@@ -0,0 +1,2 @@
+#include "script_component.hpp"
+#include "XEH_PREP.hpp"

addons/smoke/config.cpp

@@ -0,0 +1,16 @@
+#include "script_component.hpp"
+
+class CfgPatches {
+    class ADDON {
+        name = QUOTE(COMPONENT);
+        units[] = {};
+        weapons[] = {};
+        requiredVersion = REQUIRED_VERSION;
+        requiredAddons[] = {"ace_main"};
+        VERSION_CONFIG;
+    };
+};
+
+#include "CfgEventHandlers.hpp"
+#include "CfgGlasses.hpp"
+#include "ACE_Arsenal_Stats.hpp"

addons/smoke/functions/fnc_isInSmoke.sqf

@@ -0,0 +1,43 @@
+#include "..\script_component.hpp"
+/*
+ * Author: BrettMayson
+ * Check if a unit is in smoke (or any thick particle effect that has `blockAIVisibility`)
+ *
+ * Arguments:
+ * 0: Unit <OBJECT>
+ *
+ * Return Value:
+ * Is the unit in smoke? <BOOL>
+ *
+ * Example:
+ * [player] call ace_smoke_fnc_isInSmoke
+ *
+ * Public: Yes
+ */
+
+params ["_unit"];
+
+private _coverage = 0;
+
+private _eyePos = eyePos _unit;
+private _positions = [
+    [_eyePos, _eyePos vectorAdd [5, 0, 0], _unit],
+    [_eyePos, _eyePos vectorAdd [-5, 0, 0], _unit],
+    [_eyePos, _eyePos vectorAdd [0, 5, 0], _unit],
+    [_eyePos, _eyePos vectorAdd [0, -5, 0], _unit]
+];
+
+{
+    private _intersect = lineIntersectsSurfaces _x;
+    if (_intersect isNotEqualTo []) then {
+        _x set [1, _intersect select 0 select 0];
+    };
+    // Check visibility can return 0 for really close surfaces
+    if ((_x#0) distance (_x#1) < 0.05) then {
+        _coverage = _coverage + 1;
+    } else {
+        _coverage = _coverage + ([objNull, "VIEW"] checkVisibility [_x#0, _x#1]);
+    };
+} forEach _positions;
+
+_coverage < ((count _positions) / 2)

addons/smoke/functions/fnc_pfh.sqf

@@ -0,0 +1,75 @@
+#include "..\script_component.hpp"
+/*
+ * Author: BrettMayson
+ * Per Frame Handler that updates smoke effects on units
+ *
+ * Arguments:
+ * 0: Unit <OBJECT>
+ *
+ * Return Value:
+ * Nothing <NOTHING>
+ *
+ * Example:
+ * [{
+ *   [player] call ace_smoke_fnc_pfh
+ * }] call CBA_fnc_addPerFrameHandler
+ *
+ * Public: No
+ */
+
+params ["_unit"];
+
+private _isInSmoke = [_unit] call FUNC(isInSmoke);
+
+private _change = (if (_isInSmoke) then {
+    0.175 * GVAR(effectFactor)
+} else {
+    -0.04 * GVAR(recoveryFactor)
+}) * diag_deltaTime;
+
+// Eyes
+private _levelEyes = _unit getVariable [QGVAR(eyesLevel), 0];
+private _newLevelEyes = _levelEyes + _change;
+_newLevelEyes = _newLevelEyes min 1;
+_newLevelEyes = _newLevelEyes max 0;
+
+private _eyesProtect = _unit getVariable [QGVAR(eyesProtection), false];
+if (_eyesProtect != 0) then {
+    _levelEyes = _levelEyes * (1 - _eyesProtect);
+};
+_unit setVariable [QGVAR(eyesLevel), _levelEyes, true];
+
+private _dynamicBlurValue = linearConversion [0.2, 1, _levelEyes, 0, 0.8, true];
+private _colorCorrectionsValue = linearConversion [0.2, 1, _levelEyes, 1, 0.6, true];
+
+if (_unit == ace_player) then {
+    GVAR(ppHandleDynamicBlur) ppEffectAdjust [_dynamicBlurValue];
+    GVAR(ppHandleColorCorrections) ppEffectAdjust [1,1,0,[0,0,0,0],[0.8, 0.8, 0.8, _colorCorrectionsValue],[1,1,1,0]];
+
+    GVAR(ppHandleDynamicBlur) ppEffectCommit 0;
+    GVAR(ppHandleColorCorrections) ppEffectCommit 0;
+};
+
+// Breathing
+private _levelBreathing = _unit getVariable [QGVAR(breathingLevel), 0];
+private _newLevelBreathing = _levelBreathing + _change;
+_newLevelBreathing = _newLevelBreathing min 1;
+_newLevelBreathing = _newLevelBreathing max 0;
+
+private _breathProtect = _unit getVariable [QGVAR(breathingProtection), false];
+if (_breathProtect != 0) then {
+    _levelBreathing = _levelBreathing * (1 - _breathProtect);
+};
+_unit setVariable [QGVAR(breathingLevel), _levelBreathing, true];
+
+private _breathingEffectiveness = linearConversion [0.2, 1, _levelBreathing, 1, 0.6, true];
+if !(isNil "ace_medical_vitals_fnc_addSpO2DutyFactor") then {
+    [ADDON, _breathingEffectiveness] call ace_medical_vitals_fnc_addSpO2DutyFactor;
+};
+
+// Event
+private _smoked = _unit getVariable [QGVAR(smoked), false];
+if (_isInSmoke != _smoked) then {
+    [QGVAR(smoked), _isInSmoke] call CBA_fnc_localEvent;
+};
+_unit setVariable [QGVAR(smoked), _isInSmoke, true];

addons/smoke/initSettings.inc.sqf

@@ -0,0 +1,46 @@
+private _category = format ["ACE %1", localize LSTRING(DisplayName)];
+
+[
+    QGVAR(enabled), "CHECKBOX",
+    [LSTRING(enabled_DisplayName), LSTRING(enabled_Description)],
+    _category,
+    true,
+    1,
+    {
+        [QGVAR(enabled), _this] call EFUNC(common,cbaSettings_settingChanged);
+        GVAR(ppHandleDynamicBlur) ppEffectEnable _this;
+        GVAR(ppHandleColorCorrections) ppEffectEnable _this;
+        if (_this) then {
+            if (GVAR(pfh) == -1) then {
+                GVAR(pfh) = [{
+                    [ace_player] call FUNC(pfh);
+                }] call CBA_fnc_addPerFrameHandler;
+            };
+        } else {
+            if (GVAR(pfh) != -1) then {
+                [GVAR(pfh)] call CBA_fnc_removePerFrameHandler;
+                GVAR(pfh) = -1;
+            };
+        };
+    }
+] call CBA_fnc_addSetting;
+
+[
+    QGVAR(effectFactor), "SLIDER",
+    [LSTRING(effectFactor_DisplayName), LSTRING(effectFactor_Description)],
+    _category,
+    [0, 1, 0.5, 0.1],
+    1,
+    {[QGVAR(effectFactor), _this] call EFUNC(common,cbaSettings_settingChanged)},
+    true // Needs mission restart
+] call CBA_fnc_addSetting;
+
+[
+    QGVAR(recoveryFactor), "SLIDER",
+    [LSTRING(recoveryFactor_DisplayName), LSTRING(recoveryFactor_Description)],
+    _category,
+    [0, 1, 0.5, 0.1],
+    1,
+    {[QGVAR(recoveryFactor), _this] call EFUNC(common,cbaSettings_settingChanged)},
+    true // Needs mission restart
+] call CBA_fnc_addSetting;

addons/smoke/script_component.hpp

@@ -0,0 +1,17 @@
+#define COMPONENT smoke
+#define COMPONENT_BEAUTIFIED Smoke
+#include "\z\ace\addons\main\script_mod.hpp"
+
+// #define DEBUG_MODE_FULL
+// #define DISABLE_COMPILE_CACHE
+// #define ENABLE_PERFORMANCE_COUNTERS
+
+#ifdef DEBUG_ENABLED_SMOKE
+    #define DEBUG_MODE_FULL
+#endif
+
+#ifdef DEBUG_SETTINGS_SMOKE
+    #define DEBUG_SETTINGS DEBUG_SETTINGS_SMOKE
+#endif
+
+#include "\z\ace\addons\main\script_macros.hpp"