feat: E2E gas profiling native and erc20

foundry.lock

@@ -0,0 +1,26 @@
+{
+  "lib/account-abstraction": {
+    "rev": "abff2aca61a8f0934e533d0d352978055fddbd96"
+  },
+  "lib/forge-std": {
+    "tag": {
+      "name": "v1.10.0",
+      "rev": "8bbcf6e3f8f62f419e5429a0bd89331c85c37824"
+    }
+  },
+  "lib/openzeppelin-contracts": {
+    "rev": "5705e8208bc92cd82c7bcdfeac8dbc7377767d96"
+  },
+  "lib/p256-verifier": {
+    "rev": "29475ae300ec95d98d5c7cc34c094846f0aa2dcd"
+  },
+  "lib/safe-singleton-deployer-sol": {
+    "rev": "cf2b89c33fed536c4dd6fef2fb84f39053068868"
+  },
+  "lib/solady": {
+    "rev": "c4c96607cb3aa3807b14c81ae2015bcba061f8fc"
+  },
+  "lib/webauthn-sol": {
+    "rev": "619f20ab0f074fef41066ee4ab24849a913263b2"
+  }
+}

snapshots/EndToEndTest.json

@@ -0,0 +1,6 @@
+{
+  "e2e_transfer_erc20_4337": "159402",
+  "e2e_transfer_erc20_eoa": "50910",
+  "e2e_transfer_native_4337": "159635",
+  "e2e_transfer_native_eoa": "17652"
+}

test/gas/EndToEnd.t.sol

@@ -0,0 +1,103 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.4;
+
+import {console2} from "forge-std/Test.sol";
+import {SmartWalletTestBase} from "../CoinbaseSmartWallet/SmartWalletTestBase.sol";
+import {CoinbaseSmartWallet} from "../../src/CoinbaseSmartWallet.sol";
+import {CoinbaseSmartWalletFactory} from "../../src/CoinbaseSmartWalletFactory.sol";
+import {MockTarget} from "../mocks/MockTarget.sol";
+import {UserOperation} from "account-abstraction/interfaces/UserOperation.sol";
+import {MockERC20} from "../../lib/solady/test/utils/mocks/MockERC20.sol";
+import {Static} from "../CoinbaseSmartWallet/Static.sol";
+
+/// forge-config: default.isolate = true
+contract EndToEndTest is SmartWalletTestBase {
+    address eoaUser = address(0xe0a);
+
+    MockERC20 usdc;
+    MockTarget target;
+    CoinbaseSmartWalletFactory factory;
+
+    function setUp() public override {
+        vm.etch(0x5FF137D4b0FDCD49DcA30c7CF57E578a026d2789, Static.ENTRY_POINT_BYTES);
+
+        CoinbaseSmartWallet implementation = new CoinbaseSmartWallet();
+        factory = new CoinbaseSmartWalletFactory(address(implementation));
+
+        signerPrivateKey = 0xa11ce;
+        signer = vm.addr(signerPrivateKey);
+        owners.push(abi.encode(signer));
+        account = factory.createAccount(owners, 0);
+
+        vm.deal(address(account), 100 ether);
+        vm.deal(eoaUser, 100 ether);
+
+        usdc = new MockERC20("USD Coin", "USDC", 6);
+        usdc.mint(address(account), 10000e6);
+        usdc.mint(eoaUser, 10000e6);
+
+        target = new MockTarget();
+    }
+
+    // Native ETH transfer comparison between ERC-4337 and EOA
+    function test_transfer_native() public {
+        userOpCalldata = abi.encodeCall(CoinbaseSmartWallet.execute, (address(0x1234), 1 ether, ""));
+        UserOperation memory op = _getUserOpWithSignature();
+
+        bytes memory handleOpsCalldata = abi.encodeCall(entryPoint.handleOps, (_makeOpsArray(op), payable(bundler)));
+        console2.log("test_transfer_native ERC-4337 calldata size:", handleOpsCalldata.length);
+
+        vm.startSnapshotGas("e2e_transfer_native_4337");
+        _sendUserOperation(op);
+        uint256 gas4337 = vm.stopSnapshotGas();
+        console2.log("test_transfer_native ERC-4337 gas:", gas4337);
+
+        console2.log("test_transfer_native EOA calldata size:", uint256(0));
+
+        vm.prank(eoaUser);
+        vm.startSnapshotGas("e2e_transfer_native_eoa");
+        payable(address(0x1234)).transfer(1 ether);
+        uint256 gasEOA = vm.stopSnapshotGas();
+        console2.log("test_transfer_native EOA gas:", gasEOA);
+        console2.log("Gas overhead (4337/EOA):", (gas4337 * 100) / gasEOA, "%");
+    }
+
+    // ERC20 transfer comparison between ERC-4337 and EOA
+    function test_transfer_erc20() public {
+        userOpCalldata = abi.encodeCall(
+            CoinbaseSmartWallet.execute,
+            (address(usdc), 0, abi.encodeCall(usdc.transfer, (address(0x5678), 100e6)))
+        );
+        UserOperation memory op = _getUserOpWithSignature();
+
+        bytes memory handleOpsCalldata = abi.encodeCall(entryPoint.handleOps, (_makeOpsArray(op), payable(bundler)));
+        console2.log("test_transfer_erc20 ERC-4337 calldata size:", handleOpsCalldata.length);
+
+        vm.startSnapshotGas("e2e_transfer_erc20_4337");
+        _sendUserOperation(op);
+        uint256 gas4337 = vm.stopSnapshotGas();
+        console2.log("test_transfer_erc20 ERC-4337 gas:", gas4337);
+
+        bytes memory eoaCalldata = abi.encodeCall(usdc.transfer, (address(0x5678), 100e6));
+        console2.log("test_transfer_erc20 EOA calldata size:", eoaCalldata.length);
+
+        vm.prank(eoaUser);
+        vm.startSnapshotGas("e2e_transfer_erc20_eoa");
+        usdc.transfer(address(0x5678), 100e6);
+        uint256 gasEOA = vm.stopSnapshotGas();
+        console2.log("test_transfer_erc20 EOA gas:", gasEOA);
+        console2.log("Gas overhead (4337/EOA):", (gas4337 * 100) / gasEOA, "%");
+    }
+
+    function _makeOpsArray(UserOperation memory op) internal pure returns (UserOperation[] memory) {
+        UserOperation[] memory ops = new UserOperation[](1);
+        ops[0] = op;
+        return ops;
+    }
+
+    function _sign(UserOperation memory userOp) internal view override returns (bytes memory signature) {
+        bytes32 toSign = entryPoint.getUserOpHash(userOp);
+        (uint8 v, bytes32 r, bytes32 s) = vm.sign(signerPrivateKey, toSign);
+        signature = abi.encode(CoinbaseSmartWallet.SignatureWrapper(0, abi.encodePacked(r, s, v)));
+    }
+}