Add LazyHTML.Tree.postreduce/3 and LazyHTML.Tree.prereduce/3

lib/lazy_html/tree.ex

@@ -172,6 +172,36 @@ defmodule LazyHTML.Tree do
   @doc """
   Performs a depth-first, post-order traversal of the given tree.
 
+  This function traverses the tree without modifying it, check `postwalk/2` and
+  `postwalk/3` if you need to modify the tree.
+  """
+  @spec traverse(
+          t(),
+          acc,
+          (html_node(), acc -> acc)
+        ) :: acc
+        when acc: term()
+  def traverse(tree, acc, fun), do: do_traverse(tree, acc, fun)
+
+  defp do_traverse([], acc, _fun), do: acc
+
+  defp do_traverse([node | rest], acc, fun) do
+    acc = do_traverse(node, acc, fun)
+    do_traverse(rest, acc, fun)
+  end
+
+  defp do_traverse({tag, attrs, children}, acc, fun) do
+    acc = do_traverse(children, acc, fun)
+    fun.({tag, attrs, children}, acc)
+  end
+
+  defp do_traverse(node, acc, fun) do
+    fun.(node, acc)
+  end
+
+  @doc """
+  Performs a depth-first, post-order traversal of the given tree.
+
   The mapper `fun` can return a list of nodes to replace the given
   node. In order to remove a node, return an empty list.
   """

test/lazy_html/tree_test.exs

@@ -60,6 +60,33 @@ defmodule LazyHTML.TreeTest do
     end
   end
 
+  describe "traverse/3" do
+    test "does post-order traversal of the nodes and accumulates results" do
+      tree = [
+        {:comment, "Hello world"},
+        {"div", [{"class", "root"}],
+         [
+           {"span", [], ["Hello"]},
+           {:comment, "intersection"},
+           {"span", [], ["world"]}
+         ]}
+      ]
+
+      nodes = LazyHTML.Tree.traverse(tree, [], fn node, acc -> [node | acc] end)
+
+      assert nodes == [
+               {"div", [{"class", "root"}],
+                [{"span", [], ["Hello"]}, {:comment, "intersection"}, {"span", [], ["world"]}]},
+               {"span", [], ["world"]},
+               "world",
+               {:comment, "intersection"},
+               {"span", [], ["Hello"]},
+               "Hello",
+               {:comment, "Hello world"}
+             ]
+    end
+  end
+
   describe "postwalk/3" do
     test "does post-order traversal of the nodes and accumulates results" do
       tree = [