Add LazyHTML.Tree.postreduce/3 and LazyHTML.Tree.prereduce/3

lib/lazy_html/tree.ex

@@ -172,6 +172,34 @@ defmodule LazyHTML.Tree do
   @doc """
   Performs a depth-first, post-order traversal of the given tree.
 
+  This function traverses the tree without modifying it, check `postwalk/2` and
+  `postwalk/3` if you need to modify the tree.
+  """
+  @spec postreduce(
+          t(),
+          acc,
+          (html_node(), acc -> acc)
+        ) :: acc
+        when acc: term()
+  def postreduce([], acc, _fun), do: acc
+
+  def postreduce([node | rest], acc, fun) do
+    acc = postreduce(node, acc, fun)
+    postreduce(rest, acc, fun)
+  end
+
+  def postreduce({tag, attrs, children}, acc, fun) do
+    acc = postreduce(children, acc, fun)
+    fun.({tag, attrs, children}, acc)
+  end
+
+  def postreduce(node, acc, fun) do
+    fun.(node, acc)
+  end
+
+  @doc """
+  Performs a depth-first, post-order traversal of the given tree.
+
   The mapper `fun` can return a list of nodes to replace the given
   node. In order to remove a node, return an empty list.
   """

test/lazy_html/tree_test.exs

@@ -60,6 +60,33 @@ defmodule LazyHTML.TreeTest do
     end
   end
 
+  describe "postreduce/3" do
+    test "does post-order traversal of the nodes and accumulates results" do
+      tree = [
+        {:comment, "Hello world"},
+        {"div", [{"class", "root"}],
+         [
+           {"span", [], ["Hello"]},
+           {:comment, "intersection"},
+           {"span", [], ["world"]}
+         ]}
+      ]
+
+      nodes = LazyHTML.Tree.postreduce(tree, [], fn node, acc -> [node | acc] end)
+
+      assert nodes == [
+               {"div", [{"class", "root"}],
+                [{"span", [], ["Hello"]}, {:comment, "intersection"}, {"span", [], ["world"]}]},
+               {"span", [], ["world"]},
+               "world",
+               {:comment, "intersection"},
+               {"span", [], ["Hello"]},
+               "Hello",
+               {:comment, "Hello world"}
+             ]
+    end
+  end
+
   describe "postwalk/3" do
     test "does post-order traversal of the nodes and accumulates results" do
       tree = [