Wait for user activity before notification timeout starts counting

Author: lenemter

meson.build

@@ -26,6 +26,7 @@ executable(
     'src/Confirmation.vala',
     'src/DBus.vala',
     'src/FdoActionGroup.vala',
+    'src/IdleMonitor.vala',
     'src/Notification.vala',
     'src/Widgets/MaskedImage.vala',
     css_gresource,

src/AbstractBubble.vala

@@ -128,6 +128,8 @@ public class Notifications.AbstractBubble : Gtk.Window {
 
         transparency_settings.changed["use-transparency"].connect (update_transparency);
         update_transparency ();
+
+        IdleMonitor.get_default ().notify["is-idle"].connect (check_idle_status);
     }
 
     private void update_transparency () requires (transparency_settings != null) {
@@ -146,11 +148,17 @@ public class Notifications.AbstractBubble : Gtk.Window {
 
         base.present ();
 
-        if (timeout != 0) {
+        if (!IdleMonitor.get_default ().is_idle) {
             timeout_id = Timeout.add (timeout, timeout_expired);
         }
     }
 
+    private void check_idle_status () {
+        if (!IdleMonitor.get_default ().is_idle && timeout_id == 0) {
+            Timeout.add (timeout, timeout_expired);
+        }
+    }
+
     private void pointer_enter () {
         close_revealer.reveal_child = true;
 
@@ -163,7 +171,7 @@ public class Notifications.AbstractBubble : Gtk.Window {
     private void pointer_leave () {
         close_revealer.reveal_child = false;
 
-        if (timeout != 0) {
+        if (timeout == 0) {
             timeout_id = Timeout.add (timeout, timeout_expired);
         }
     }

src/Application.vala

@@ -33,7 +33,7 @@ public class Notifications.Application : Gtk.Application {
         try {
             new Notifications.Server (connection);
         } catch (Error e) {
-            Error.prefix_literal (out e, "Registring notification server failed: ");
+            Error.prefix_literal (out e, "Registering notification server failed: ");
             throw e;
         }
 
@@ -76,6 +76,8 @@ public class Notifications.Application : Gtk.Application {
                 name_lost ();
             }
         );
+
+        IdleMonitor.get_default (); // Start listening to MutterIdleMonitor
     }
 
     public static int main (string[] args) {

src/IdleMonitor.vala

@@ -0,0 +1,45 @@
+/*
+ * SPDX-License-Identifier: GPL-3.0-or-later
+ * SPDX-FileCopyrightText: Copyright 2025 elementary, Inc. (https://elementary.io)
+ */
+
+public class Notifications.IdleMonitor : Object {
+    [DBus (name = "org.gnome.Mutter.IdleMonitor")]
+    private interface MutterIdleMonitor : Object {
+        public signal void watch_fired (uint32 id);
+        public abstract uint32 add_idle_watch (uint64 interval) throws Error;
+    }
+
+    private static GLib.Once<IdleMonitor> instance;
+    public static unowned IdleMonitor get_default () {
+        return instance.once (() => new IdleMonitor ());
+    }
+
+    private MutterIdleMonitor? idle_monitor;
+    private uint32 idle_id = 0;
+    private uint32 active_id = 0;
+
+    public bool is_idle { get; private set; default = false; }
+
+    construct {
+        Bus.get_proxy.begin<MutterIdleMonitor> (
+            SESSION, "org.gnome.Mutter.IdleMonitor", "/org/gnome/Mutter/IdleMonitor/Core", NONE, null,
+            (obj, res) => {
+                try {
+                    idle_monitor = Bus.get_proxy.end<MutterIdleMonitor> (res);
+                    idle_id = idle_monitor.add_idle_watch (30000);
+                    active_id = idle_monitor.add_idle_watch (100);
+                    idle_monitor.watch_fired.connect ((id) => {
+                        if (id == idle_id) {
+                            is_idle = true;
+                        } else if (id == active_id && is_idle) {
+                            is_idle = false;
+                        }
+                    });
+                } catch (Error e) {
+                    warning ("Couldn't connect to idle monitor: %s", e.message);
+                }
+            }
+        );
+    }
+}