Show when location services are in use

data/Indicator.css

@@ -3,6 +3,11 @@
  * SPDX-FileCopyrightText: 2023 elementary, Inc. (https://elementary.io)
  */
 
+
+quicksettings tattlebox box {
+    padding: 0.666rem; /* 6px */
+}
+
 quicksettings scalebox,
 quicksettings .togglebox {
     padding: 0.666rem; /* 6px */

po/POTFILES

@@ -11,4 +11,5 @@ src/Widgets/EndSessionDialog.vala
 src/Widgets/RotationToggle.vala
 src/Widgets/SessionBox.vala
 src/Widgets/SettingsToggle.vala
+src/Widgets/TattleBox.vala
 src/Widgets/TextScale.vala

src/DBus/GeoclueManager.vala

@@ -0,0 +1,9 @@
+/*
+ * SPDX-License-Identifier: GPL-2.0-or-later
+ * SPDX-FileCopyrightText: 2011-2024 elementary, Inc. (https://elementary.io)
+ */
+
+[DBus (name = "org.freedesktop.GeoClue2.Manager")]
+interface QuickSettings.GeoclueManager : DBusProxy {
+    public abstract bool in_use { get; }
+}

src/PopoverWidget.vala

@@ -20,6 +20,10 @@ public class QuickSettings.PopoverWidget : Gtk.Box {
     }
 
     construct {
+        var tattle_box = new TattleBox () {
+            halign = CENTER
+        };
+
         var screen_reader = new SettingsToggle (
             new ThemedIcon ("orca-symbolic"),
             _("Screen Reader")
@@ -64,6 +68,7 @@ public class QuickSettings.PopoverWidget : Gtk.Box {
         bottom_box.get_style_context ().add_class ("togglebox");
 
         var main_box = new Gtk.Box (VERTICAL, 0);
+        main_box.add (tattle_box);
         main_box.add (toggle_box);
         main_box.add (scale_box);
         main_box.add (new Gtk.Separator (HORIZONTAL));

src/Widgets/TattleBox.vala

@@ -0,0 +1,41 @@
+public class QuickSettings.TattleBox : Gtk.Bin {
+    class construct {
+        set_css_name ("tattlebox");
+    }
+
+    construct {
+        var location_image = new Gtk.Image.from_icon_name ("location-active-symbolic", MENU);
+        location_image.get_style_context ().add_class (Granite.STYLE_CLASS_ACCENT);
+        location_image.get_style_context ().add_class ("purple");
+
+        var location_label = new Gtk.Label (_("Location services in use"));
+
+        var location_box = new Gtk.Box (HORIZONTAL, 3);
+        location_box.add (location_image);
+        location_box.add (location_label);
+
+        var location_revealer = new Gtk.Revealer () {
+            child = location_box
+        };
+
+        child = location_revealer;
+
+        setup_geoclue_manager.begin ((obj, res) => {
+            var geoclue_manager = setup_geoclue_manager.end (res);
+            location_revealer.reveal_child = geoclue_manager.in_use;
+
+            geoclue_manager.g_properties_changed.connect (() => {
+                location_revealer.reveal_child = geoclue_manager.in_use;
+            });
+        });
+    }
+
+    private async GeoclueManager? setup_geoclue_manager () {
+        try {
+            return yield Bus.get_proxy (BusType.SYSTEM, "org.freedesktop.GeoClue2", "/org/freedesktop/GeoClue2/Manager");
+        } catch (Error e) {
+            info ("Unable to connect to GeoClue2 bus, location tattle tale will not be available: %s", e.message);
+            return null;
+        }
+    }
+}

src/meson.build

@@ -12,6 +12,7 @@ sources = [
     'PopoverWidget.vala',
     'DBus' / 'AccountsService.vala',
     'DBus' / 'EndSessionDialogServer.vala',
+    'DBus' / 'GeoclueManager.vala',
     'DBus' / 'LockInterface.vala',
     'DBus' / 'SensorProxy.vala',
     'DBus' / 'SessionInterface.vala',
@@ -21,6 +22,7 @@ sources = [
     'Widgets' / 'RotationToggle.vala',
     'Widgets' / 'SettingsToggle.vala',
     'Widgets' / 'SessionBox.vala',
+    'Widgets' / 'TattleBox.vala',
     'Widgets' / 'TextScale.vala',
 ]