godot/modules/svg/SCsub at d69120e01d8c0f70a3c63db5456031d2ccda6d18 · godotengine/godot · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
#!/usr/bin/env python
from misc.utility.scons_hints import *

Import("env")
Import("env_modules")

env_svg = env_modules.Clone()

# Thirdparty source files

thirdparty_obj = []

thirdparty_dir = "#thirdparty/thorvg/"
thirdparty_sources = [
    # common
    "src/common/tvgCompressor.cpp",
    "src/common/tvgMath.cpp",
    "src/common/tvgStr.cpp",
    # SVG parser
    "src/loaders/svg/tvgSvgCssStyle.cpp",
    "src/loaders/svg/tvgSvgLoader.cpp",
    "src/loaders/svg/tvgSvgPath.cpp",
    "src/loaders/svg/tvgSvgSceneBuilder.cpp",
    "src/loaders/svg/tvgSvgUtil.cpp",
    "src/loaders/svg/tvgXmlParser.cpp",
    "src/loaders/raw/tvgRawLoader.cpp",
    # image loaders
    "src/loaders/external_png/tvgPngLoader.cpp",
    # renderer common
    "src/renderer/tvgAccessor.cpp",
    # "src/renderer/tvgAnimation.cpp",
    "src/renderer/tvgCanvas.cpp",
    "src/renderer/tvgFill.cpp",
    # "src/renderer/tvgGlCanvas.cpp",
    "src/renderer/tvgInitializer.cpp",
    "src/renderer/tvgLoader.cpp",
    "src/renderer/tvgPaint.cpp",
    "src/renderer/tvgPicture.cpp",
    "src/renderer/tvgRender.cpp",
    # "src/renderer/tvgSaver.cpp",
    "src/renderer/tvgScene.cpp",
    "src/renderer/tvgShape.cpp",
    "src/renderer/tvgSwCanvas.cpp",
    "src/renderer/tvgTaskScheduler.cpp",
    "src/renderer/tvgText.cpp",
    # "src/renderer/tvgWgCanvas.cpp",
    # renderer sw_engine
    "src/renderer/sw_engine/tvgSwFill.cpp",
    "src/renderer/sw_engine/tvgSwImage.cpp",
    "src/renderer/sw_engine/tvgSwMath.cpp",
    "src/renderer/sw_engine/tvgSwMemPool.cpp",
    "src/renderer/sw_engine/tvgSwPostEffect.cpp",
    "src/renderer/sw_engine/tvgSwRaster.cpp",
    "src/renderer/sw_engine/tvgSwRenderer.cpp",
    "src/renderer/sw_engine/tvgSwRle.cpp",
    "src/renderer/sw_engine/tvgSwShape.cpp",
    "src/renderer/sw_engine/tvgSwStroke.cpp",
]

if env.editor_build:
    thirdparty_sources += [
        "src/renderer/tvgAnimation.cpp",
        # Lottie loader
        "src/loaders/lottie/tvgLottieAnimation.cpp",
        "src/loaders/lottie/tvgLottieBuilder.cpp",
        # "src/loaders/lottie/tvgLottieExpressions.cpp",
        "src/loaders/lottie/tvgLottieInterpolator.cpp",
        "src/loaders/lottie/tvgLottieLoader.cpp",
        "src/loaders/lottie/tvgLottieModel.cpp",
        "src/loaders/lottie/tvgLottieModifier.cpp",
        "src/loaders/lottie/tvgLottieParser.cpp",
        "src/loaders/lottie/tvgLottieParserHandler.cpp",
    ]

if env["module_webp_enabled"]:
    thirdparty_sources += ["src/loaders/external_webp/tvgWebpLoader.cpp"]
    env_svg.Append(CPPDEFINES=["THORVG_WEBP_LOADER_SUPPORT"])
if env["module_jpg_enabled"]:
    thirdparty_sources += ["src/loaders/external_jpg/tvgJpgLoader.cpp"]
    env_svg.Append(CPPDEFINES=["THORVG_JPG_LOADER_SUPPORT"])

thirdparty_sources = [thirdparty_dir + file for file in thirdparty_sources]

env_svg.Prepend(CPPEXTPATH=[thirdparty_dir + "inc"])

# Enable ThorVG static object linking.
env_svg.Append(CPPDEFINES=["TVG_STATIC"])
# Explicit support for embedded images in svg.
env_svg.Append(CPPDEFINES=["THORVG_FILE_IO_SUPPORT"])

if env.editor_build:
    env_svg.Append(CPPDEFINES=["THORVG_LOTTIE_LOADER_SUPPORT", "LOTTIE_ENABLED"])

env_thirdparty = env_svg.Clone()
env_thirdparty.disable_warnings()
env_thirdparty.Prepend(
    CPPEXTPATH=[
        thirdparty_dir + "src/common",
        thirdparty_dir + "src/loaders/svg",
        thirdparty_dir + "src/renderer",
        thirdparty_dir + "src/renderer/sw_engine",
        thirdparty_dir + "src/loaders/raw",
        thirdparty_dir + "src/loaders/external_png",
    ]
)

if env.editor_build:
    env_thirdparty.Prepend(CPPEXTPATH=[thirdparty_dir + "src/loaders/lottie"])
if env["builtin_libpng"]:
    env_thirdparty.Prepend(CPPEXTPATH=["#thirdparty/libpng"])
if env["module_webp_enabled"]:
    env_thirdparty.Prepend(CPPEXTPATH=[thirdparty_dir + "src/loaders/external_webp"])
    if env["builtin_libwebp"]:
        env_thirdparty.Prepend(CPPEXTPATH=["#thirdparty/libwebp/src"])
if env["module_jpg_enabled"]:
    env_thirdparty.Prepend(CPPEXTPATH=[thirdparty_dir + "src/loaders/external_jpg"])
    if env["builtin_libjpeg_turbo"]:
        env_thirdparty.Prepend(CPPEXTPATH=["#thirdparty/libjpeg-turbo/src"])

env_thirdparty.add_source_files(thirdparty_obj, thirdparty_sources)
env.modules_sources += thirdparty_obj

# Godot source files

module_obj = []

env_svg.add_source_files(module_obj, "*.cpp")
if env.editor_build:
    env_svg.add_source_files(module_obj, "editor/*.cpp")

env.modules_sources += module_obj

# Needed to force rebuilding the module files when the thirdparty library is updated.
env.Depends(module_obj, thirdparty_obj)