migrate regex operations to HH\Lib\Regex (#117)

Author: jjergus

src/CodegenClass.hack

@@ -9,7 +9,7 @@
 
 namespace Facebook\HackCodegen;
 
-use namespace HH\Lib\{Str, Vec};
+use namespace HH\Lib\{Regex, Str};
 
 /**
  * Generate code for a class.
@@ -119,11 +119,10 @@ final class CodegenClass extends CodegenClassish {
     if ($param_full !== null) {
       // Extract variable names from parameters
       $param_names = vec[];
-      $re = '/\$[a-zA-Z_\x7f-\xff][a-zA-Z0-9_\x7f-\xff]*/';
+      $re = re"/\\\$[a-zA-Z_\\x7f-\\xff][a-zA-Z0-9_\\x7f-\\xff]*/";
       foreach ($param_full as $str) {
-        $matches = array();
-        if (\preg_match_all($re, $str, &$matches)) {
-          $param_names = Vec\concat($param_names, $matches[0]);
+        foreach (Regex\every_match($str, $re) as $match) {
+          $param_names[] = $match[0];
         }
       }
       $params_str = \implode(', ', $param_names);

src/SignedSourceBase.hack

@@ -9,6 +9,8 @@
 
 namespace Facebook\HackCodegen;
 
+use namespace HH\Lib\{C, Keyset, Regex, Str, Vec};
+
 abstract class SignedSourceBase {
 
   const TOKEN = '<<SignedSource::*O*zOeWoEQle#+L!plEphiEmie@I>>';
@@ -23,8 +25,10 @@ abstract class SignedSourceBase {
     return $file_data;
   }
 
-  public static function getPattern(): string {
-    return '/@'.static::getTokenName().' (?:SignedSource<<([a-f0-9]{32})>>)/';
+  public static function getPattern(
+  ): Regex\Pattern<shape('token_name' => string, 'signature' => string, ...)> {
+    return
+      re"/@(?<token_name>\\S+) (?:SignedSource<<(?<signature>[a-f0-9]{32})>>)/";
   }
 
   /**
@@ -68,7 +72,10 @@ abstract class SignedSourceBase {
    *
    */
   public static function isSigned(string $file_data): bool {
-    return (bool)\preg_match(static::getPattern(), $file_data);
+    return C\any(
+      Regex\every_match($file_data, static::getPattern()),
+      $match ==> $match['token_name'] === static::getTokenName(),
+    );
   }
 
   /**
@@ -80,15 +87,25 @@ abstract class SignedSourceBase {
    *
    */
   public static function verifySignature(string $file_data): bool {
-    $matches = array();
-    if (!\preg_match(static::getPattern(), $file_data, &$matches)) {
+    $signatures =
+      Regex\every_match($file_data, static::getPattern())
+      |> Vec\filter($$, $m ==> $m['token_name'] === static::getTokenName())
+      |> Keyset\map($$, $m ==> $m['signature']);
+
+    if (C\is_empty($signatures)) {
       throw new \Exception('Can not verify the signature of an unsigned file.');
+    } else if (C\count($signatures) > 1) {
+      throw new \Exception('File has multiple different signatures.');
     }
-    $replaced_data =
-      \str_replace('SignedSource<<'.$matches[1].'>>', static::TOKEN, $file_data);
 
-    $signature = \md5(static::preprocess($replaced_data));
-    return $signature === $matches[1];
+    $signature = C\onlyx($signatures);
+
+    $expected_signature = $file_data
+      |> Str\replace($$, 'SignedSource<<'.$signature.'>>', static::TOKEN)
+      |> static::preprocess($$)
+      |> \md5($$);
+
+    return $signature === $expected_signature;
   }
 
   /**