Add counts of deps and rev-deps in the list of packages

bin/opam2web.ml

@@ -82,8 +82,8 @@ let make_website user_options universe statistics ds =
     O2wBlog.make_menu ~srcurl:user_options.blog_source_uri blog_entries
   in
   let blog_feed = O2wBlog.make_feed ~root:user_options.root_uri blog_entries in
-  let criteria = ["name"; "popularity"; "date"] in
-  let criteria_nostats = ["name"; "date"] in
+  let criteria = ["name"; "popularity"; "date"; "rev-deps"] in
+  let criteria_nostats = ["name"; "date"; "rev-deps"] in
   let sortby_links =
     match statistics with
     | None   ->
@@ -106,8 +106,21 @@ let make_website user_options universe statistics ds =
       menu_item = No_menu (1, to_html ~active:"date" ~compare_pkg);
       menu_srcurl = None;
     } in
+    let revdeps =
+      let compare_pkg =
+        O2wPackage.compare_revdeps universe.rev_depends
+      in
+      {
+        menu_source = content_dir;
+        menu_link = Uri.make ~path:(packages_prefix^"/index-rev-deps.html") ();
+        menu_link_text = "Packages";
+        menu_link_html = Html.string "Packages";
+        menu_item = No_menu (1, to_html ~active:"rev-deps" ~compare_pkg);
+        menu_srcurl = None;
+      }
+    in
     match universe.name_popularity with
-    | None -> [ date ]
+    | None -> [ revdeps; date ]
     | Some s ->
       let compare_pkg =
         O2wPackage.compare_popularity ~reverse:true s
@@ -120,7 +133,7 @@ let make_website user_options universe statistics ds =
         menu_item = No_menu (1, to_html ~active:"popularity" ~compare_pkg);
         menu_srcurl = None;
       } in
-      [ popularity; date ]
+      [ popularity; revdeps; date ]
   in
   include_files user_options.out_dir user_options.files_dir;
   let about_page =

content/universe.xhtml

@@ -20,6 +20,8 @@
           <th>Name</th>
           <th>Latest version</th>
           <th>Description</th>
+          <th>Rev-deps</th>
+          <th>Dep-cone</th>
         </tr>
       </thead>
       <t:insert name="pkgs" />

src/o2wPackage.ml

@@ -52,6 +52,18 @@ let compare_popularity ?(reverse = false) pkg_stats p1 p2 =
     Int64.compare c1 c2
   | _ -> compare_alphanum p1 p2
 
+(* Comparison function using the number of reverse dependencies for each package *)
+let compare_revdeps rev_depends p1 p2 =
+  let pkg_count pkg =
+    match OpamPackage.Map.find_opt pkg rev_depends with
+    | None -> 0
+    | Some rdeps ->
+      OpamPackage.Name.Set.cardinal (OpamPackage.names_of_packages rdeps)
+  in
+  match pkg_count p1, pkg_count p2 with
+  | c1, c2 when c1 <> c2 -> compare c2 c1
+  | _ -> compare_alphanum p1 p2
+
 (* Comparison function using the publication time of packages *)
 let compare_date ?(reverse = false) pkg_dates p1 p2 =
   let pkg_date pkg =

src/o2wPackage.mli

@@ -25,6 +25,10 @@ val compare_alphanum: package -> package -> int
 val compare_date: ?reverse:bool -> float package_map ->
   package -> package -> int
 
+(** Compare packages by number of reverse dependencies, most first *)
+val compare_revdeps: package_set package_map ->
+  package -> package -> int
+
 (** Compare packages by popularity *)
 val compare_popularity: ?reverse:bool -> int64 name_map ->
   package -> package -> int

src/o2wTypes.mli

@@ -23,6 +23,10 @@ type univ = {
   version_downloads: (int64 package_map * (package * package_set) OpamStd.String.Map.t) option;
   depends: package_set package_map;
   rev_depends: package_set package_map;
+  (** Number of distinct package names in each package's dependency cone, itself included.
+      An over-approximation of the output of [opam list --rec --required-by], because we
+      include packages of every platform (os, arch, ...). *)
+  dependency_cone_sizes: int package_map;
   depopts: package_set package_map;
   rev_depopts: package_set package_map;
 }

src/o2wUniverse.ml

@@ -113,6 +113,75 @@ let rev_depends deps =
             (OpamPackage.Set.add pkg) OpamPackage.Set.empty))
     deps OpamPackage.Map.empty
 
+
+(* Dependencies used for the dependency cone. They differ from [depends] above.
+   They are an approximation of what [opam list --required-by] would show because we cannot
+   resolve variables that need a switch (os, arch, ...). To avoid including dependencies of multiple platforms
+   (say both linux and macos), we remove disjunctions (by picking a single branch).
+
+   [filter_default] is true to match OpamSwitchState.dependencies, which keeps a dependency whose
+   filter it cannot decide.
+ *)
+let rec remove_disjunction = function
+ | (OpamFormula.Empty as x) | (Atom _ as x) -> x
+ | Block x -> remove_disjunction x
+ | And (a, b) -> And (remove_disjunction a, remove_disjunction b)
+ | Or (a, _) -> remove_disjunction a
+
+let cone_depends st =
+ OpamPackage.Map.fold (fun pkg opam ->
+   let deps =
+     OpamFormula.packages st.OpamStateTypes.packages @@
+     remove_disjunction @@
+     OpamPackageVar.all_depends ~build:true ~post:false ~test:false
+       ~doc:false ~dev_setup:false ~depopts:false ~filter_default:true
+       st opam
+     in
+     OpamPackage.Map.add pkg deps)
+   st.opams OpamPackage.Map.empty
+
+
+(* A graph where nodes are packages and there is an edge a->b if package a depends on package b. *)
+module PkgGraph = struct
+  type t = package_set package_map
+  module V = OpamPackage
+  let iter_vertex f deps = OpamPackage.Map.iter (fun pkg _ -> f pkg) deps
+  let iter_succ f deps pkg =
+    match OpamPackage.Map.find_opt pkg deps with
+    | None -> ()
+    | Some pkgs -> OpamPackage.Set.iter f pkgs
+end
+
+module PkgTopo = Graph.Topological.Make (PkgGraph)
+
+let dependency_cone_sizes depends =
+  (* packages in reverse topological order *)
+  let pkgs = PkgTopo.fold (fun pkg acc -> pkg :: acc) depends [] in
+  let cones =
+    List.fold_left (fun acc pkg ->
+        let deps =
+          OpamStd.Option.default OpamPackage.Set.empty
+            (OpamPackage.Map.find_opt pkg depends)
+        in
+        (* Some packages include [ocaml] as a dependency. We remove [ocaml] from their cone to avoid including
+           also ocaml-base-compiler, ocaml-option-bytecode-only, ...
+           Except for [ocaml] itself, for which we want to see the full cone. *)
+        let deps = match OpamPackage.Name.to_string (OpamPackage.name pkg) with
+          | "ocaml" -> deps
+          | _ -> OpamPackage.Set.filter (fun p -> OpamPackage.Name.to_string p.name <> "ocaml") deps
+        in
+        let cone =
+          OpamPackage.Set.fold (fun dep cone ->
+              match OpamPackage.Map.find_opt dep acc with
+              | Some dep_cone -> OpamPackage.Name.Set.union dep_cone cone
+              | None -> cone)
+            deps (OpamPackage.Name.Set.singleton pkg.name)
+        in
+        OpamPackage.Map.add pkg cone acc)
+      OpamPackage.Map.empty pkgs
+  in
+  OpamPackage.Map.map OpamPackage.Name.Set.cardinal cones
+
 let to_page ~prefix universe pkg acc =
   try
     if Unix.isatty Unix.stdout then
@@ -241,6 +310,8 @@ let load statistics repo_roots =
   let rdeps = rev_depends deps in
   let depopts = depends st OpamFile.OPAM.depopts in
   let rev_depopts = rev_depends depopts in
+  Printf.printf "++ Computing dependency cones.\n%!";
+  let dependency_cone_sizes = dependency_cone_sizes (cone_depends st) in
   Printf.printf "++ Getting package modification dates from git.\n%!";
   let dates = dates st in
   let version_downloads, name_popularity =
@@ -262,6 +333,7 @@ let load statistics repo_roots =
     name_popularity;
     depends = deps;
     rev_depends = rdeps;
+    dependency_cone_sizes;
     depopts;
     rev_depopts;
   }
@@ -314,6 +386,19 @@ let to_html ~content_dir ~sortby_links ~active ~compare_pkg univ =
             ]
             | None -> []
           in
+          (* Number of reverse dependencies *)
+          let pkg_nb_rev_depends =
+            match OpamPackage.Map.find_opt pkg univ.rev_depends with
+            | None -> 0
+            | Some rdeps ->
+              OpamPackage.Name.Set.cardinal (OpamPackage.names_of_packages rdeps)
+          in
+          (* Size of the dependency cone: everything an installation of this
+             package pulls in, itself included. *)
+          let pkg_dependency_cone_size =
+            OpamStd.Option.default 0
+              (OpamPackage.Map.find_opt pkg univ.dependency_cone_sizes)
+          in
           let tags = String.concat " " (OpamFile.OPAM.tags pkg_info) in
           let pkg_tags = if tags = "" then [] else ["Tags: "^tags] in
           let pkg_tooltip = String.concat " | " (pkg_download @ pkg_published @ pkg_tags) in
@@ -329,7 +414,9 @@ let to_html ~content_dir ~sortby_links ~active ~compare_pkg univ =
                 (Html.a ~href:pkg_href
                    (Html.string (OpamPackage.name_to_string pkg)))
               @ Html.tag "td" (Html.string (OpamPackage.version_to_string pkg))
-              @ Html.tag "td" synopsis))
+              @ Html.tag "td" synopsis
+              @ Html.tag "td" (Html.int pkg_nb_rev_depends)
+              @ Html.tag "td" (Html.int pkg_dependency_cone_size)))
           :: acc)
       []
       (List.rev sorted_packages)