SF: Add operation extract to retrieve a single dataset from a multi ds result

The API is: extract(multi_dataset, index)

extract returns a single dataset.

Added test

Author: MichaelHuth

Packages/MIES/MIES_Constants.ipf

@@ -2522,6 +2522,7 @@ StrConstant SF_OP_TPSS                = "tpss"
 StrConstant SF_OP_TPINST              = "tpinst"
 StrConstant SF_OP_TPBASE              = "tpbase"
 StrConstant SF_OP_TPFIT               = "tpfit"
+StrConstant SF_OP_EXTRACT             = "extract"
 ///@}
 
 /// @name SF operations shorts

Packages/MIES/MIES_SweepFormula.ipf

@@ -70,7 +70,7 @@ Function/WAVE SF_GetNamedOperations()
 	                  SF_OP_MERGE, SF_OP_FIT, SF_OP_FITLINE, SF_OP_DATASET, SF_OP_SELECTVIS, SF_OP_SELECTCM, SF_OP_SELECTSTIMSET,       \
 	                  SF_OP_SELECTIVSCCSWEEPQC, SF_OP_SELECTIVSCCSETQC, SF_OP_SELECTRANGE, SF_OP_SELECTEXP, SF_OP_SELECTDEV,            \
 	                  SF_OP_SELECTEXPANDSCI, SF_OP_SELECTEXPANDRAC, SF_OP_SELECTSETCYCLECOUNT, SF_OP_SELECTSETSWEEPCOUNT,               \
-	                  SF_OP_SELECTSCIINDEX, SF_OP_SELECTRACINDEX, SF_OP_ANAFUNCPARAM, SF_OP_CONCAT}
+	                  SF_OP_SELECTSCIINDEX, SF_OP_SELECTRACINDEX, SF_OP_ANAFUNCPARAM, SF_OP_CONCAT, SF_OP_EXTRACT}
 
 	return wt
 End

Packages/MIES/MIES_SweepFormula_Executor.ipf

@@ -469,6 +469,9 @@ Function/WAVE SFE_FormulaExecutor(STRUCT SF_ExecutionData &exd, [variable srcLoc
 		case SF_OP_DATASET:
 			WAVE out = SFO_OperationDataset(exdop)
 			break
+		case SF_OP_EXTRACT:
+			WAVE out = SFO_OperationExtract(exdop)
+			break
 		case SF_OP_SELECTVIS:
 			WAVE out = SFOS_OperationSelectVis(exdop)
 			break

Packages/MIES/MIES_SweepFormula_Operations.ipf

@@ -742,6 +742,24 @@ Function/WAVE SFO_OperationDataset(STRUCT SF_ExecutionData &exd)
 	return SFH_GetOutputForExecutor(output, exd.graph, SF_OP_DATASET)
 End
 
+// extract(<dataset>, index)
+Function/WAVE SFO_OperationExtract(STRUCT SF_ExecutionData &exd)
+
+	variable idx
+	string opShort = SF_OP_EXTRACT
+
+	SFH_CheckArgumentCount(exd, opShort, 2, maxArgs = 2)
+
+	WAVE/WAVE datasets = SFH_GetArgumentAsWave(exd, opShort, 0)
+	idx = SFH_GetArgumentAsNumeric(exd, opShort, 1)
+	SFH_ASSERT(idx < DimSize(datasets, ROWS), "index out of range")
+
+	WAVE/WAVE output = SFH_CreateSFRefWave(exd.graph, opShort, 1)
+	output[0] = datasets[idx]
+
+	return SFH_GetOutputForExecutor(output, exd.graph, opShort)
+End
+
 Function/WAVE SFO_OperationDerivative(STRUCT SF_ExecutionData &exd)
 
 	variable numArgs

Packages/tests/Basic/UTF_SweepFormula_Operations.ipf

@@ -3631,3 +3631,56 @@ static Function TestOperationAnaFuncParam()
 		idx += 1
 	endfor
 End
+
+static Function TestOperationExtract()
+
+	string str, wavePath
+	string win
+
+	win = GetDataBrowserWithData()
+
+	str = "extract(1)"
+	try
+		WAVE data = SFE_ExecuteFormula(str, win, singleResult = 1, useVariables = 0)
+		FAIL()
+	catch
+		PASS()
+	endtry
+
+	str = "extract(1,1,1)"
+	try
+		WAVE data = SFE_ExecuteFormula(str, win, singleResult = 1, useVariables = 0)
+		FAIL()
+	catch
+		PASS()
+	endtry
+
+	str = "extract(1,a)"
+	try
+		WAVE data = SFE_ExecuteFormula(str, win, singleResult = 1, useVariables = 0)
+		FAIL()
+	catch
+		PASS()
+	endtry
+
+	str = "extract(1,0)"
+	WAVE data = SFE_ExecuteFormula(str, win, singleResult = 1, useVariables = 0)
+	CHECK_EQUAL_WAVES(data, {1}, mode = WAVE_DATA)
+
+	str = "extract(a,0)"
+	WAVE data = SFE_ExecuteFormula(str, win, singleResult = 1, useVariables = 0)
+	Make/FREE/T ref = {"a"}
+	CHECK_EQUAL_WAVES(data, ref, mode = WAVE_DATA)
+
+	str = "extract([1,2],0)"
+	WAVE data = SFE_ExecuteFormula(str, win, singleResult = 1, useVariables = 0)
+	CHECK_EQUAL_WAVES(data, {1, 2}, mode = WAVE_DATA)
+
+	str = "extract(dataset(1,2),0)"
+	WAVE data = SFE_ExecuteFormula(str, win, singleResult = 1, useVariables = 0)
+	CHECK_EQUAL_WAVES(data, {1}, mode = WAVE_DATA)
+
+	str = "extract(dataset(1,2),1)"
+	WAVE data = SFE_ExecuteFormula(str, win, singleResult = 1, useVariables = 0)
+	CHECK_EQUAL_WAVES(data, {2}, mode = WAVE_DATA)
+End