Add hash functions for strings, numbers and waves

These uses XXH3-64 for IP10 and CRC for IP9.

Author: t-b

Packages/MIES/MIES_Constants.ipf

@@ -2318,6 +2318,7 @@ Constant SUBWINDOW_MOVE_CORRECTION = 5
 /// @anchor HashMethods
 ///@{
 Constant HASH_SHA2_256 = 1
+Constant HASH_XXH3_64  = 102
 ///@}
 
 // see DisplayHelpTopic "LoadWave"

Packages/MIES/MIES_Utilities_Algorithm.ipf

@@ -1275,3 +1275,65 @@ Function FindSequenceReverseWrapper(WAVE sequence, WAVE source)
 		start      = foundIndex + 1
 	endfor
 End
+
+/// @brief Return a hash of `str` taking `previousHash` into account
+///
+/// Uses `XXH3-64` on IP10 and CRC on IP9. Can not be used for security purposes.
+threadsafe Function/S HashString(string previousHash, string str)
+
+	variable crc
+
+#if IgorVersion() >= 10
+	return Hash(previousHash + str, HASH_XXH3_64)
+#endif
+
+	if(IsEmpty(previousHash))
+		crc = 0
+	else
+		crc = str2num(previousHash)
+	endif
+
+#ifdef AUTOMATED_TESTING
+	ASSERT_TS(IsFinite(crc), "Expected previousHash to be a number:" + previousHash)
+#endif // AUTOMATED_TESTING
+
+	return num2istr(StringCRC(crc, str)) // NOLINT
+End
+
+/// @brief Return a hash of `wv` taking `previousHash` into account
+///
+/// Uses `XXH3-64` on IP10 and CRC on IP9. Can not be used for security purposes.
+threadsafe Function/S HashWave(string previousHash, WAVE/Z wv)
+
+	variable crc
+
+	ASSERT_TS(WaveExists(wv), "Missing wv")
+
+#if IgorVersion() >= 10
+	return previousHash + WaveHash(wv, HASH_XXH3_64)
+#endif
+
+	if(IsEmpty(previousHash))
+		crc = 0
+	else
+		crc = str2num(previousHash)
+	endif
+
+#ifdef AUTOMATED_TESTING
+	ASSERT_TS(IsFinite(crc), "Expected previousHash to be a number:" + previousHash)
+#endif // AUTOMATED_TESTING
+
+	return num2istr(WaveCRC(crc, wv)) // NOLINT
+End
+
+/// @brief Return a hash of `num` taking `previousHash` into account
+///
+/// The conversion to string is done with full double precision.
+///
+/// Uses `XXH3-64` on IP10 and CRC on IP9. Can not be used for security purposes.
+threadsafe Function/S HashNumber(string previousHash, variable num)
+
+	string str = num2strHighPrec(num, precision = MAX_DOUBLE_PRECISION, shorten = 1)
+
+	return HashString(previousHash, str)
+End

Packages/tests/Basic/UTF_Utils_Algorithm.ipf

@@ -1326,3 +1326,50 @@ static Function TestFindSequenceReverseWrapper()
 End
 
 /// @}
+
+static Function TestHashString()
+
+#if IgorVersion() >= 10
+	CHECK_EQUAL_STR(HashString("", ""), "2d06800538d394c2")
+	CHECK_EQUAL_STR(HashString("123", "b"), "3c9cec9e7b5026a6")
+#else
+	CHECK_EQUAL_STR(HashString("", ""), "0")
+	CHECK_EQUAL_STR(HashString("123", "b"), "3060352845")
+#endif
+
+End
+
+static Function TestHashNumber()
+
+#if IgorVersion() >= 10
+	CHECK_EQUAL_STR(HashNumber("", NaN), "bacd09c7db647d0d")
+	CHECK_EQUAL_STR(HashNumber("123", 456), "507f6d6059ff79de")
+#else
+	CHECK_EQUAL_STR(HashNumber("", NaN), "1810114945")
+	CHECK_EQUAL_STR(HashNumber("123", 456), "3909895360")
+#endif
+
+End
+
+static Function TestHashWave()
+
+	try
+		HashWave("", $"")
+		FAIL()
+	catch
+		CHECK_NO_RTE()
+	endtry
+
+	Make/T/FREE/N=0 empty
+	Make/R/FREE some = {456}
+
+#if IgorVersion() >= 10
+	CHECK_EQUAL_STR(HashWave("", empty), "2d06800538d394c2")
+	// outputted hash is prefixed with previousHash (123)
+	CHECK_EQUAL_STR(HashWave("123", some), "12338bbb7f4fc6cddb1")
+#else
+	CHECK_EQUAL_STR(HashWave("", empty), "0")
+	CHECK_EQUAL_STR(HashWave("123", some), "1220402755")
+#endif
+
+End