SF: Add tooltip information to table display

The tooltip displays a selection of properties of the data when available
The properties can be set in SF_GetTableTooltipProperties

The tooltip function attempts automatically to read it as string or number.

Author: MichaelHuth

Packages/MIES/MIES_Constants.ipf

@@ -2124,6 +2124,7 @@ StrConstant SF_META_TRACE_MODE         = "/TraceMode"        // number, one of @
 StrConstant SF_META_TRACETOFRONT       = "/TraceToFront"     // number, boolean, defaults to false (0)
 StrConstant SF_META_DONOTPLOT          = "/DoNotPlot"        // number, boolean, defaults to false (0)
 StrConstant SF_META_WINDOW_HOOK        = "/WindowHook"       // string
+StrConstant SF_META_FORMULA            = "/Formula"          // string
 
 /// A color group allows to have matching colors for sweep data with the same channel type/number and sweep.
 /// It is applied before the matching headstage/average colors in #SF_GetTraceColor().

Packages/MIES/MIES_SweepFormula.ipf

@@ -201,6 +201,7 @@ static Function [WAVE/WAVE formulaResults, STRUCT SF_PlotMetaData plotMetaData]
 			endif
 
 			formulaResults[i][%FORMULAY] = wvYdata
+			JWN_SetStringInWaveNote(wvYdata, SF_META_FORMULA, yFormula)
 		endif
 	endfor
 
@@ -594,6 +595,7 @@ static Function/S SF_NewSweepFormulaBaseWindow(string templateName, string graph
 			NewPanel/N=$win/K=1/W=(150, 400, 1000, 700)
 		elseif(winType == WINTYPE_TABLE)
 			Edit/N=$win/K=1/W=(150, 400, 1000, 700)
+			SetWindow $S_name, tooltipHook(sfTableTooltip)=SF_TableTooltipHook
 		else
 			FATAL_ERROR("Unsupported window type")
 		endif
@@ -608,7 +610,7 @@ End
 static Function [WAVE/T plotGraphs, WAVE/WAVE infos] SF_PreparePlotter(string winNameTemplate, string graph, variable winDisplayMode, variable numGraphs)
 
 	variable i, guidePos, restoreCursorInfo
-	string panelName, guideName1, guideName2, win, winTable, winNameTemplateTable
+	string panelName, guideName1, guideName2, win, winTable, winNameTemplateTable, subWinName
 
 	ASSERT(numGraphs > 0, "Can not prepare plotter window for zero graphs")
 
@@ -679,6 +681,8 @@ static Function [WAVE/T plotGraphs, WAVE/WAVE infos] SF_PreparePlotter(string wi
 			Display/HOST=$win/FG=(customLeft, $guideName1, customRight, $guideName2)/N=$("Graph" + num2str(i))
 			plotGraphs[i][%GRAPH] = win + "#" + S_name
 			Edit/HOST=$winTable/FG=(customLeft, $guideName1, customRight, $guideName2)/N=$("Table" + num2str(i))
+			subWinName = winTable + "#" + S_name
+			SetWindow $subWinName, tooltipHook(sfTableTooltip)=SF_TableTooltipHook
 			plotGraphs[i][%TABLE] = winTable + "#" + S_name
 		endfor
 	endif
@@ -2384,3 +2388,50 @@ static Function SF_MarkErrorLocationInNotebook(string win)
 	offset    = str2num(varAssignments[V_row][%OFFSET])
 	Notebook $sfWin, selection={(paragraph, 0), (paragraph, offset - 1)}, textRGB=(65535, 0, 0)
 End
+
+/// @brief This function returns a list of JSON properties that are intended to be shown
+///        in the tooltip for table display, when present
+///        This allows to separate meta data for the user from internal meta information like plotting hints
+static Function/WAVE SF_GetTableTooltipProperties()
+
+	Make/FREE/T wv = {SF_META_FORMULA, SF_META_EXPERIMENT, SF_META_DEVICE, SF_META_SWEEPNO, SF_META_CHANNELTYPE, SF_META_CHANNELNUMBER}
+
+	return wv
+End
+
+Function SF_TableTooltipHook(STRUCT WMTooltipHookStruct &s)
+
+	variable hookResult, val
+	string str, prop, key
+
+	if(WaveExists(s.yWave))
+		hookResult = 1
+		s.tooltip  = ""
+
+		WAVE/T props = SF_GetTableTooltipProperties()
+		for(prop : props)
+			key = prop[1, Inf]
+			str = JWN_GetStringFromWaveNote(s.yWave, prop)
+			if(!IsEmpty(str))
+				str        = ReplaceString("\r", str, "")
+				s.tooltip += "<b>" + key + ": </b>" + str + "<br>"
+				continue
+			endif
+			val = JWN_GetNumberFromWaveNote(s.yWave, prop)
+			if(IsNaN(val))
+				continue
+			endif
+			if(!CmpStr(prop, SF_META_CHANNELTYPE))
+				str        = ChannelTypeToString(val)
+				s.tooltip += "<b>" + key + ": </b>" + str + "<br>"
+				continue
+			endif
+			s.tooltip += "<b>" + key + ": </b>" + num2str(val) + "<br>"
+		endfor
+		s.tooltip     = RemoveEnding(s.tooltip, "<br>")
+		s.isHtml      = 1
+		s.duration_ms = 600000
+	endif
+
+	return hookResult
+End