GUI util: Add utility function to remove all columns from a table

This is the equivalent for RemoveTracesFromGraph for plots with the
base functionality.

Function:
RemoveAllColumnsFromTable

Author: MichaelHuth

Packages/MIES/MIES_Utilities_GUI.ipf

@@ -661,6 +661,24 @@ Function RemoveTracesFromGraph(string graph, [string trace, WAVE/Z wv, DFREF dfr
 	return NaN
 End
 
+/// @brief Removes all wave columns from a table
+///
+/// @param win name of a window containing a table
+Function RemoveAllColumnsFromTable(string win)
+
+	ASSERT(WinType(win) == WINTYPE_TABLE, "Target window must be a table")
+
+	for(;;)
+		WAVE/Z wv = WaveRefIndexed(win, 0, 3)
+		if(!WaveExists(wv))
+			break
+		endif
+		// the order of the columnSpec subTypes is very important here
+		// see WM issue #7689
+		RemoveFromTable/W=$win wv.id, wv.ld, wv.i, wv.l, wv.d
+	endfor
+End
+
 /// @brief Add user data "panelVersion" to the panel
 Function AddVersionToPanel(string win, variable version)
 

Packages/tests/Basic/UTF_Utils_GUI.ipf

@@ -158,3 +158,60 @@ Function TestIsExteriorSubWindow()
 	CHECK(IsExteriorSubWindow(main + "#" + sub0))
 	CHECK(!IsExteriorSubWindow(main + "#" + sub0 + "#" + sub1))
 End
+
+Function TestRemoveAllColumnsFromTable()
+
+	string win
+	string wName1 = "racft1"
+	string wName2 = "racft2"
+	string wName3 = "racft3"
+
+	try
+		RemoveAllColumnsFromTable("IdoNotExist")
+		FAIL()
+	catch
+		PASS()
+	endtry
+
+	Display/N=myPlot
+	win = S_name
+	try
+		RemoveAllColumnsFromTable(win)
+		FAIL()
+	catch
+		PASS()
+	endtry
+	KillWindow/Z $win
+
+	KillWaves/Z $wName1, $wName2, $wName3
+	Make $wName1/WAVE=wv1
+	Make $wName2/WAVE=wv2
+	Make/N=(1, 1) $wName3/WAVE=wv3
+
+	Edit/N=myTable wv1
+	win = S_name
+
+	RemoveAllColumnsFromTable(win)
+	WAVE/Z wvremain = WaveRefIndexed(win, 0, 3)
+	CHECK_WAVE(wvremain, NULL_WAVE)
+	KillWindow/Z $win
+
+	Edit/N=myTable wv1
+	win = S_name
+	AppendToTable/W=$win wv2
+
+	RemoveAllColumnsFromTable(win)
+	WAVE/Z wvremain = WaveRefIndexed(win, 0, 3)
+	CHECK_WAVE(wvremain, NULL_WAVE)
+	KillWindow/Z $win
+
+	Edit/N=myTable wv3
+	win = S_name
+
+	RemoveAllColumnsFromTable(win)
+	WAVE/Z wvremain = WaveRefIndexed(win, 0, 3)
+	CHECK_WAVE(wvremain, NULL_WAVE)
+	KillWindow/Z $win
+
+	KillWaves/Z $wName1, $wName2, $wName3
+End