Add msgSender() to V4Quoter

snapshots/QuoterTest.json

@@ -1,15 +1,15 @@
 {
-  "Quoter_exactInputSingle_oneForZero_multiplePositions": "145902",
-  "Quoter_exactInputSingle_zeroForOne_multiplePositions": "152117",
-  "Quoter_exactOutputSingle_oneForZero": "79267",
-  "Quoter_exactOutputSingle_zeroForOne": "84512",
-  "Quoter_quoteExactInput_oneHop_1TickLoaded": "122728",
-  "Quoter_quoteExactInput_oneHop_initializedAfter": "147363",
-  "Quoter_quoteExactInput_oneHop_startingInitialized": "80638",
-  "Quoter_quoteExactInput_twoHops": "204942",
-  "Quoter_quoteExactOutput_oneHop_1TickLoaded": "122224",
-  "Quoter_quoteExactOutput_oneHop_2TicksLoaded": "152879",
-  "Quoter_quoteExactOutput_oneHop_initializedAfter": "122251",
-  "Quoter_quoteExactOutput_oneHop_startingInitialized": "98545",
-  "Quoter_quoteExactOutput_twoHops": "204670"
+  "Quoter_exactInputSingle_oneForZero_multiplePositions": "146134",
+  "Quoter_exactInputSingle_zeroForOne_multiplePositions": "152349",
+  "Quoter_exactOutputSingle_oneForZero": "79477",
+  "Quoter_exactOutputSingle_zeroForOne": "84722",
+  "Quoter_quoteExactInput_oneHop_1TickLoaded": "122938",
+  "Quoter_quoteExactInput_oneHop_initializedAfter": "147573",
+  "Quoter_quoteExactInput_oneHop_startingInitialized": "80848",
+  "Quoter_quoteExactInput_twoHops": "205152",
+  "Quoter_quoteExactOutput_oneHop_1TickLoaded": "122434",
+  "Quoter_quoteExactOutput_oneHop_2TicksLoaded": "153089",
+  "Quoter_quoteExactOutput_oneHop_initializedAfter": "122461",
+  "Quoter_quoteExactOutput_oneHop_startingInitialized": "98755",
+  "Quoter_quoteExactOutput_twoHops": "204880"
 }

src/base/BaseActionsRouter.sol

@@ -5,10 +5,11 @@ import {IPoolManager} from "@uniswap/v4-core/src/interfaces/IPoolManager.sol";
 import {SafeCallback} from "./SafeCallback.sol";
 import {CalldataDecoder} from "../libraries/CalldataDecoder.sol";
 import {ActionConstants} from "../libraries/ActionConstants.sol";
+import {IMsgSender} from "../interfaces/IMsgSender.sol";
 
 /// @notice Abstract contract for performing a combination of actions on Uniswap v4.
 /// @dev Suggested uint256 action values are defined in Actions.sol, however any definition can be used
-abstract contract BaseActionsRouter is SafeCallback {
+abstract contract BaseActionsRouter is IMsgSender, SafeCallback {
     using CalldataDecoder for bytes;
 
     /// @notice emitted when different numbers of parameters and actions are provided

src/interfaces/IMsgSender.sol

@@ -0,0 +1,13 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+/// @title IMsgSender
+/// @notice Interface for contracts that expose the original caller
+interface IMsgSender {
+    /// @notice Returns the address of the original caller (msg.sender)
+    /// @dev Uniswap v4 periphery contracts implement a callback pattern which lose
+    /// the original msg.sender caller context. This view function provides a way for
+    /// integrating contracts (e.g. hooks) to access the original caller address.
+    /// @return The address of the original caller
+    function msgSender() external view returns (address);
+}

src/interfaces/IV4Quoter.sol

@@ -5,10 +5,11 @@ import {PoolKey} from "@uniswap/v4-core/src/types/PoolKey.sol";
 import {Currency} from "@uniswap/v4-core/src/types/Currency.sol";
 import {PathKey} from "../libraries/PathKey.sol";
 import {IImmutableState} from "./IImmutableState.sol";
+import {IMsgSender} from "./IMsgSender.sol";
 
 /// @title IV4Quoter
 /// @notice Interface for the V4Quoter contract
-interface IV4Quoter is IImmutableState {
+interface IV4Quoter is IImmutableState, IMsgSender {
     struct QuoteExactSingleParams {
         PoolKey poolKey;
         bool zeroForOne;

src/lens/V4Quoter.sol

@@ -10,6 +10,8 @@ import {IV4Quoter} from "../interfaces/IV4Quoter.sol";
 import {PathKey} from "../libraries/PathKey.sol";
 import {QuoterRevert} from "../libraries/QuoterRevert.sol";
 import {BaseV4Quoter} from "../base/BaseV4Quoter.sol";
+import {Locker} from "../libraries/Locker.sol";
+import {IMsgSender} from "../interfaces/IMsgSender.sol";
 
 /// @title V4Quoter
 /// @notice Supports quoting the delta amounts for exact input or exact output swaps.
@@ -20,9 +22,16 @@ contract V4Quoter is IV4Quoter, BaseV4Quoter {
 
     constructor(IPoolManager _poolManager) BaseV4Quoter(_poolManager) {}
 
+    modifier setMsgSender() {
+        Locker.set(msg.sender);
+        _; // execute the function
+        Locker.set(address(0)); // reset the locker
+    }
+
     /// @inheritdoc IV4Quoter
     function quoteExactInputSingle(QuoteExactSingleParams memory params)
         external
+        setMsgSender
         returns (uint256 amountOut, uint256 gasEstimate)
     {
         uint256 gasBefore = gasleft();
@@ -37,6 +46,7 @@ contract V4Quoter is IV4Quoter, BaseV4Quoter {
     /// @inheritdoc IV4Quoter
     function quoteExactInput(QuoteExactParams memory params)
         external
+        setMsgSender
         returns (uint256 amountOut, uint256 gasEstimate)
     {
         uint256 gasBefore = gasleft();
@@ -51,6 +61,7 @@ contract V4Quoter is IV4Quoter, BaseV4Quoter {
     /// @inheritdoc IV4Quoter
     function quoteExactOutputSingle(QuoteExactSingleParams memory params)
         external
+        setMsgSender
         returns (uint256 amountIn, uint256 gasEstimate)
     {
         uint256 gasBefore = gasleft();
@@ -65,6 +76,7 @@ contract V4Quoter is IV4Quoter, BaseV4Quoter {
     /// @inheritdoc IV4Quoter
     function quoteExactOutput(QuoteExactParams memory params)
         external
+        setMsgSender
         returns (uint256 amountIn, uint256 gasEstimate)
     {
         uint256 gasBefore = gasleft();
@@ -138,4 +150,10 @@ contract V4Quoter is IV4Quoter, BaseV4Quoter {
         uint256 amountIn = params.zeroForOne ? uint128(-swapDelta.amount0()) : uint128(-swapDelta.amount1());
         amountIn.revertQuote();
     }
+
+    /// @inheritdoc IMsgSender
+    function msgSender() external view returns (address) {
+        // despite using the Locker library, V4Quoter does not have a reentrancy lock
+        return Locker.get();
+    }
 }

test/V4Quoter.t.sol

@@ -6,6 +6,7 @@ import {Test} from "forge-std/Test.sol";
 import {PathKey} from "../src/libraries/PathKey.sol";
 import {Deploy, IV4Quoter} from "../test/shared/Deploy.sol";
 import {BaseV4Quoter} from "../src/base/BaseV4Quoter.sol";
+import {MockMsgSenderHook} from "./mocks/MockMsgSenderHook.sol";
 
 // v4-core
 import {LiquidityAmounts} from "@uniswap/v4-core/test/utils/LiquidityAmounts.sol";
@@ -19,6 +20,7 @@ import {IPoolManager} from "@uniswap/v4-core/src/interfaces/IPoolManager.sol";
 import {Currency} from "@uniswap/v4-core/src/types/Currency.sol";
 import {TickMath} from "@uniswap/v4-core/src/libraries/TickMath.sol";
 import {StateLibrary} from "@uniswap/v4-core/src/libraries/StateLibrary.sol";
+import {Hooks} from "@uniswap/v4-core/src/libraries/Hooks.sol";
 
 // solmate
 import {MockERC20} from "solmate/src/test/utils/mocks/MockERC20.sol";
@@ -48,6 +50,7 @@ contract QuoterTest is Test, Deployers {
     PoolKey key01;
     PoolKey key02;
     PoolKey key12;
+    PoolKey key01Hook;
 
     MockERC20[] tokenPath;
 
@@ -70,11 +73,18 @@ contract QuoterTest is Test, Deployers {
         token2 = MockERC20(address(0x3333));
         token2.mint(address(this), 2 ** 128);
 
+        // deploy a hook that reads msgSender
+        MockMsgSenderHook msgSenderHook = new MockMsgSenderHook();
+        address mockMsgSenderHookAddr = address(uint160(Hooks.BEFORE_SWAP_FLAG | Hooks.AFTER_SWAP_FLAG));
+        vm.etch(mockMsgSenderHookAddr, address(msgSenderHook).code);
+
         key01 = createPoolKey(token0, token1, address(0));
         key02 = createPoolKey(token0, token2, address(0));
         key12 = createPoolKey(token1, token2, address(0));
+        key01Hook = createPoolKey(token0, token1, mockMsgSenderHookAddr);
         setupPool(key01);
         setupPool(key12);
+        setupPool(key01Hook);
         setupPoolMultiplePositions(key02);
     }
 
@@ -439,6 +449,24 @@ contract QuoterTest is Test, Deployers {
         assertEq(amountIn, 10000);
     }
 
+    function test_fuzz_quoter_msgSender(address pranker, bool zeroForOne, bool exactInput) public {
+        IV4Quoter.QuoteExactSingleParams memory params = IV4Quoter.QuoteExactSingleParams({
+            poolKey: key01Hook,
+            zeroForOne: zeroForOne,
+            exactAmount: 10000,
+            hookData: ZERO_BYTES
+        });
+
+        vm.expectEmit(true, true, true, true);
+        emit MockMsgSenderHook.BeforeSwapMsgSender(pranker);
+
+        vm.expectEmit(true, true, true, true);
+        emit MockMsgSenderHook.AfterSwapMsgSender(pranker);
+
+        vm.prank(pranker);
+        exactInput ? quoter.quoteExactInputSingle(params) : quoter.quoteExactOutputSingle(params);
+    }
+
     function createPoolKey(MockERC20 tokenA, MockERC20 tokenB, address hookAddr)
         internal
         pure

test/mocks/MockMsgSenderHook.sol

@@ -0,0 +1,35 @@
+// SPDX-License-Identifier: UNLICENSED
+pragma solidity ^0.8.20;
+
+import {IPoolManager} from "@uniswap/v4-core/src/interfaces/IPoolManager.sol";
+import {PoolKey} from "@uniswap/v4-core/src/types/PoolKey.sol";
+import {Hooks} from "@uniswap/v4-core/src/libraries/Hooks.sol";
+import {BalanceDelta} from "@uniswap/v4-core/src/types/BalanceDelta.sol";
+import {BaseTestHooks} from "@uniswap/v4-core/src/test/BaseTestHooks.sol";
+import {BeforeSwapDelta, BeforeSwapDeltaLibrary} from "@uniswap/v4-core/src/types/BeforeSwapDelta.sol";
+import {IMsgSender} from "../../src/interfaces/IMsgSender.sol";
+
+contract MockMsgSenderHook is BaseTestHooks {
+    event BeforeSwapMsgSender(address msgSender);
+    event AfterSwapMsgSender(address msgSender);
+
+    function beforeSwap(address periphery, PoolKey calldata, IPoolManager.SwapParams calldata, bytes calldata)
+        external
+        override
+        returns (bytes4, BeforeSwapDelta, uint24)
+    {
+        emit BeforeSwapMsgSender(IMsgSender(periphery).msgSender());
+        return (BaseTestHooks.beforeSwap.selector, BeforeSwapDeltaLibrary.ZERO_DELTA, 0);
+    }
+
+    function afterSwap(
+        address periphery,
+        PoolKey calldata,
+        IPoolManager.SwapParams calldata,
+        BalanceDelta,
+        bytes calldata
+    ) external override returns (bytes4, int128) {
+        emit AfterSwapMsgSender(IMsgSender(periphery).msgSender());
+        return (BaseTestHooks.afterSwap.selector, 0);
+    }
+}