-
Notifications
You must be signed in to change notification settings - Fork 203
/
Copy pathriscv_insts_vext_fp_vm.sail
executable file
·136 lines (113 loc) · 5.27 KB
/
riscv_insts_vext_fp_vm.sail
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
/*=======================================================================================*/
/* This Sail RISC-V architecture model, comprising all files and */
/* directories except where otherwise noted is subject the BSD */
/* two-clause license in the LICENSE file. */
/* */
/* SPDX-License-Identifier: BSD-2-Clause */
/*=======================================================================================*/
/* ******************************************************************************* */
/* This file implements part of the vector extension. */
/* Mask instructions from Chap 13 (floating-point) */
/* ******************************************************************************* */
/* ******************************* OPFVV (VVMTYPE) ******************************* */
/* FVVM instructions' destination is a mask register */
union clause ast = FVVMTYPE : (fvvmfunct6, bits(1), vregidx, vregidx, vregidx)
mapping encdec_fvvmfunct6 : fvvmfunct6 <-> bits(6) = {
FVVM_VMFEQ <-> 0b011000,
FVVM_VMFLE <-> 0b011001,
FVVM_VMFLT <-> 0b011011,
FVVM_VMFNE <-> 0b011100
}
mapping clause encdec = FVVMTYPE(funct6, vm, vs2, vs1, vd)
<-> encdec_fvvmfunct6(funct6) @ vm @ encdec_vreg(vs2) @ encdec_vreg(vs1) @ 0b001 @ encdec_vreg(vd) @ 0b1010111
when extensionEnabled(Ext_V)
function clause execute(FVVMTYPE(funct6, vm, vs2, vs1, vd)) = {
let rm_3b = fcsr[FRM];
let SEW = get_sew();
let LMUL_pow = get_lmul_pow();
let num_elem = get_num_elem(LMUL_pow, SEW);
if illegal_fp_vd_unmasked(SEW, rm_3b) then { handle_illegal(); return RETIRE_FAIL };
assert(SEW != 8);
let vm_val = read_vmask(num_elem, vm, zvreg);
let vs1_val = read_vreg(num_elem, SEW, LMUL_pow, vs1);
let vs2_val = read_vreg(num_elem, SEW, LMUL_pow, vs2);
let vd_val = read_vmask(num_elem, 0b0, vd);
let (initial_result, mask) = init_masked_result_cmp(num_elem, SEW, LMUL_pow, vd_val, vm_val);
var result = initial_result;
foreach (i from 0 to (num_elem - 1)) {
if mask[i] == bitone then {
let res : bool = match funct6 {
FVVM_VMFEQ => fp_eq(vs2_val[i], vs1_val[i]),
FVVM_VMFNE => ~(fp_eq(vs2_val[i], vs1_val[i])),
FVVM_VMFLE => fp_le(vs2_val[i], vs1_val[i]),
FVVM_VMFLT => fp_lt(vs2_val[i], vs1_val[i])
};
result[i] = bool_to_bit(res)
}
};
write_vmask(num_elem, vd, result);
set_vstart(zeros());
RETIRE_SUCCESS
}
mapping fvvmtype_mnemonic : fvvmfunct6 <-> string = {
FVVM_VMFEQ <-> "vmfeq.vv",
FVVM_VMFLE <-> "vmfle.vv",
FVVM_VMFLT <-> "vmflt.vv",
FVVM_VMFNE <-> "vmfne.vv"
}
mapping clause assembly = FVVMTYPE(funct6, vm, vs2, vs1, vd)
<-> fvvmtype_mnemonic(funct6) ^ spc() ^ vreg_name(vd) ^ sep() ^ vreg_name(vs2) ^ sep() ^ vreg_name(vs1) ^ maybe_vmask(vm)
/* ******************************* OPFVF (VFMTYPE) ******************************* */
/* VFM instructions' destination is a mask register */
union clause ast = FVFMTYPE : (fvfmfunct6, bits(1), vregidx, fregidx, vregidx)
mapping encdec_fvfmfunct6 : fvfmfunct6 <-> bits(6) = {
VFM_VMFEQ <-> 0b011000,
VFM_VMFLE <-> 0b011001,
VFM_VMFLT <-> 0b011011,
VFM_VMFNE <-> 0b011100,
VFM_VMFGT <-> 0b011101,
VFM_VMFGE <-> 0b011111
}
mapping clause encdec = FVFMTYPE(funct6, vm, vs2, rs1, vd)
<-> encdec_fvfmfunct6(funct6) @ vm @ encdec_vreg(vs2) @ encdec_freg(rs1) @ 0b101 @ encdec_vreg(vd) @ 0b1010111
when extensionEnabled(Ext_V)
function clause execute(FVFMTYPE(funct6, vm, vs2, rs1, vd)) = {
let rm_3b = fcsr[FRM];
let SEW = get_sew();
let LMUL_pow = get_lmul_pow();
let num_elem = get_num_elem(LMUL_pow, SEW);
if illegal_fp_vd_unmasked(SEW, rm_3b) then { handle_illegal(); return RETIRE_FAIL };
assert(SEW != 8);
let vm_val = read_vmask(num_elem, vm, zvreg);
let rs1_val = get_scalar_fp(rs1, SEW);
let vs2_val = read_vreg(num_elem, SEW, LMUL_pow, vs2);
let vd_val = read_vmask(num_elem, 0b0, vd);
let (initial_result, mask) = init_masked_result_cmp(num_elem, SEW, LMUL_pow, vd_val, vm_val);
var result = initial_result;
foreach (i from 0 to (num_elem - 1)) {
if mask[i] == bitone then {
let res : bool = match funct6 {
VFM_VMFEQ => fp_eq(vs2_val[i], rs1_val),
VFM_VMFNE => ~(fp_eq(vs2_val[i], rs1_val)),
VFM_VMFLE => fp_le(vs2_val[i], rs1_val),
VFM_VMFLT => fp_lt(vs2_val[i], rs1_val),
VFM_VMFGE => fp_ge(vs2_val[i], rs1_val),
VFM_VMFGT => fp_gt(vs2_val[i], rs1_val)
};
result[i] = bool_to_bit(res)
}
};
write_vmask(num_elem, vd, result);
set_vstart(zeros());
RETIRE_SUCCESS
}
mapping fvfmtype_mnemonic : fvfmfunct6 <-> string = {
VFM_VMFEQ <-> "vmfeq.vf",
VFM_VMFLE <-> "vmfle.vf",
VFM_VMFLT <-> "vmflt.vf",
VFM_VMFNE <-> "vmfne.vf",
VFM_VMFGT <-> "vmfgt.vf",
VFM_VMFGE <-> "vmfge.vf"
}
mapping clause assembly = FVFMTYPE(funct6, vm, vs2, rs1, vd)
<-> fvfmtype_mnemonic(funct6) ^ spc() ^ vreg_name(vd) ^ sep() ^ vreg_name(vs2) ^ sep() ^ freg_name(rs1) ^ maybe_vmask(vm)